From: Patrice Clement <monsieurp@gentoo.org>
Date: Sat, 1 Apr 2017 23:19:31 +0000 (+0200)
Subject: dev-java/junit: EAPI 6 bump.
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=7d2058adfc56d3667675ed8236654e4240a5dcef;p=gentoo.git

dev-java/junit: EAPI 6 bump.

Package-Manager: Portage-2.3.3, Repoman-2.3.1
---

diff --git a/dev-java/junit/junit-3.8.2-r2.ebuild b/dev-java/junit/junit-3.8.2-r2.ebuild
new file mode 100644
index 000000000000..7cf51fa048ae
--- /dev/null
+++ b/dev-java/junit/junit-3.8.2-r2.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple
+
+MY_P=${P/-/}
+
+DESCRIPTION="Simple framework to write repeatable tests"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.zip"
+HOMEPAGE="http://www.junit.org/"
+LICENSE="CPL-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+DEPEND=">=virtual/jdk-1.6"
+RDEPEND=">=virtual/jre-1.6"
+
+DOCS=( README.html cpl-v10.html )
+
+JAVA_SRC_DIR="${PN}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}" || die
+	unzip src.jar || die
+}
+
+src_prepare() {
+	default
+	java-pkg_clean
+}
+
+src_install() {
+	java-pkg-simple_src_install
+	einstalldocs
+}