From: Matt Turner <mattst88@gentoo.org>
Date: Sat, 26 May 2018 22:54:36 +0000 (-0700)
Subject: media-libs/libglvnd: Add package
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=79c3c3652df8a25c05d94f9acaaf303a5ddca270;p=gentoo.git

media-libs/libglvnd: Add package

package.mask'd for now.

Bug: https://bugs.gentoo.org/606924
---

diff --git a/media-libs/libglvnd/Manifest b/media-libs/libglvnd/Manifest
new file mode 100644
index 000000000000..c47bf92a2f18
--- /dev/null
+++ b/media-libs/libglvnd/Manifest
@@ -0,0 +1 @@
+DIST libglvnd-1.0.0.20180524.tar.gz 796997 BLAKE2B 75c50d2eb864b84e97af5b5f0c9bfde2651436acbad323312ca8b88df8cfa4dd170a743748e8c2269f39d9cb492d6ffaabd66a76ffca3062be2462adca4c79cd SHA512 3e49e4647b50f04dd534282b2f7ae76d84ea3dcd071771492a6560ae327d6167fcd071d32c447af097e68d84e6560d6b2c2b00d1409664e8b6a628b49ccdbdad
diff --git a/media-libs/libglvnd/libglvnd-1.0.0.20180524.ebuild b/media-libs/libglvnd/libglvnd-1.0.0.20180524.ebuild
new file mode 100644
index 000000000000..b1d53c3d68eb
--- /dev/null
+++ b/media-libs/libglvnd/libglvnd-1.0.0.20180524.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+EGIT_REPO_URI="https://github.com/NVIDIA/${PN}.git"
+
+if [[ ${PV} = 9999* ]]; then
+	GIT_ECLASS="git-r3"
+fi
+
+PYTHON_COMPAT=( python2_7 )
+inherit autotools ${GIT_ECLASS} multilib-minimal python-any-r1
+
+DESCRIPTION="The GL Vendor-Neutral Dispatch library"
+HOMEPAGE="https://github.com/NVIDIA/libglvnd"
+if [[ ${PV} = 9999* ]]; then
+	SRC_URI=""
+else
+	KEYWORDS="~amd64"
+	COMMIT="8709003ffdc905d144855c3117a31da220149d4c"
+	SRC_URI="https://github.com/NVIDIA/${PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	S=${WORKDIR}/${PN}-${COMMIT}
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE=""
+
+RDEPEND="
+	!media-libs/mesa[-libglvnd(-)]
+	x11-libs/libX11[${MULTILIB_USEDEP}]
+	"
+DEPEND="${PYTHON_DEPS}
+	${RDEPEND}"
+
+src_unpack() {
+	default
+	[[ $PV = 9999* ]] && git-r3_src_unpack
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} econf
+}
+
+multilib_src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
diff --git a/media-libs/libglvnd/libglvnd-9999.ebuild b/media-libs/libglvnd/libglvnd-9999.ebuild
new file mode 100644
index 000000000000..9f9f724cecc2
--- /dev/null
+++ b/media-libs/libglvnd/libglvnd-9999.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+EGIT_REPO_URI="https://github.com/NVIDIA/${PN}.git"
+
+if [[ ${PV} = 9999* ]]; then
+	GIT_ECLASS="git-r3"
+fi
+
+PYTHON_COMPAT=( python2_7 )
+inherit autotools ${GIT_ECLASS} multilib-minimal python-any-r1
+
+DESCRIPTION="The GL Vendor-Neutral Dispatch library"
+HOMEPAGE="https://github.com/NVIDIA/libglvnd"
+if [[ ${PV} = 9999* ]]; then
+	SRC_URI=""
+else
+	KEYWORDS="~amd64"
+	COMMIT=""
+	SRC_URI="https://github.com/NVIDIA/${PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	S=${WORKDIR}/${PN}-${COMMIT}
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE=""
+
+RDEPEND="
+	!media-libs/mesa[-libglvnd(-)]
+	x11-libs/libX11[${MULTILIB_USEDEP}]
+	"
+DEPEND="${PYTHON_DEPS}
+	${RDEPEND}"
+
+src_unpack() {
+	default
+	[[ $PV = 9999* ]] && git-r3_src_unpack
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} econf
+}
+
+multilib_src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
diff --git a/media-libs/libglvnd/metadata.xml b/media-libs/libglvnd/metadata.xml
new file mode 100644
index 000000000000..7a349da8f2d1
--- /dev/null
+++ b/media-libs/libglvnd/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>x11@gentoo.org</email>
+		<name>X11</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">NVIDIA/libglvnd</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/profiles/package.mask b/profiles/package.mask
index bfdbb981c431..0ab611cfedf3 100644
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -29,6 +29,11 @@
 
 #--- END OF EXAMPLES ---
 
+# Matt Turner <mattst88@gentoo.org> (25 May 2018)
+# New package. Needs to interact with media-libs/mesa and
+# x11-drivers/nvidia-drivers. Work in progress.
+media-libs/libglvnd
+
 # Andreas Sturmlechner <asturm@gentoo.org> (24 May 2018)
 # Depends on dead Qt4. Masked for removal in 30 days. Bug #629018
 dev-libs/libattica