From: Michał Górny <mgorny@gentoo.org>
Date: Wed, 16 Jan 2019 13:50:11 +0000 (+0100)
Subject: dev-python/clang-python: Add a live ebuild for 8.* branch
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=77780f02dd10bdd91a68379ba9169ca38c7dd9b5;p=gentoo.git

dev-python/clang-python: Add a live ebuild for 8.* branch

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---

diff --git a/dev-python/clang-python/clang-python-8.0.9999.ebuild b/dev-python/clang-python/clang-python-8.0.9999.ebuild
new file mode 100644
index 000000000000..180856dc03bb
--- /dev/null
+++ b/dev-python/clang-python/clang-python-8.0.9999.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6,3_7} )
+inherit git-r3 python-r1
+
+DESCRIPTION="Python bindings for sys-devel/clang"
+HOMEPAGE="https://llvm.org/"
+SRC_URI=""
+EGIT_REPO_URI="https://git.llvm.org/git/clang.git
+	https://github.com/llvm-mirror/clang.git"
+EGIT_BRANCH="release_80"
+
+LICENSE="UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# The module is opening libclang.so directly, and doing some blasphemy
+# on top of it.
+RDEPEND="
+	>=sys-devel/clang-${PV}:*
+	!sys-devel/llvm:0[clang(-),python(-)]
+	!sys-devel/clang:0[python(-)]
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${P}/bindings/python
+
+src_unpack() {
+	git-r3_fetch
+	git-r3_checkout '' '' '' bindings/python
+}
+
+python_test() {
+	"${EPYTHON}" -m unittest discover -v || die "Tests fail with ${EPYTHON}"
+}
+
+src_test() {
+	python_foreach_impl python_test
+}
+
+src_install() {
+	python_foreach_impl python_domodule clang
+}