From: Dan Molik <dan@danmolik.com>
Date: Tue, 5 Feb 2019 12:51:44 +0000 (-0500)
Subject: app-admin/terraform: add DOCS and post-install instructions.
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=741c18278755f8ef6420ecbbc58e5eeb7fd96c79;p=gentoo.git

app-admin/terraform: add DOCS and post-install instructions.

Package-Manager: Portage-2.3.59, Repoman-2.3.12
Signed-off-by: Dan Molik <dan@danmolik.com>
Closes: https://github.com/gentoo/gentoo/pull/10987
Signed-off-by: Patrice Clement <monsieurp@gentoo.org>
---

diff --git a/app-admin/terraform/terraform-0.11.11-r1.ebuild b/app-admin/terraform/terraform-0.11.11-r1.ebuild
new file mode 100644
index 000000000000..7fbea19820fc
--- /dev/null
+++ b/app-admin/terraform/terraform-0.11.11-r1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit golang-vcs-snapshot
+
+DESCRIPTION="A tool for building, changing, and combining infrastructure safely"
+HOMEPAGE="https://www.terraform.io/"
+
+EGO_PN="github.com/hashicorp/${PN}"
+SRC_URI="https://github.com/hashicorp/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+DEPEND=">=dev-lang/go-1.11.0"
+
+DOCS="README.md CHANGELOG.md"
+
+src_compile() {
+	cd "src/${EGO_PN}" || die
+	GOPATH="${S}" GOCACHE="${T}/go-cache" go build \
+		-v -work -o "${S}/${PN}" ./ || die
+}
+
+src_install() {
+	dobin terraform
+
+	pushd "src/${EGO_PN}" || die
+	einstalldocs
+	popd || die
+}
+
+pkg_postinst() {
+	elog "If you would like to install shell completions please run:"
+	elog "    terraform -install-autocomplete"
+}