From: Anthony G. Basile <blueness@gentoo.org>
Date: Wed, 13 Jul 2016 19:06:50 +0000 (-0400)
Subject: net-analyzer/ike-scan: add libressl support
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=5cb31a34447ba8c29a6dbf4061b702bb904493f2;p=gentoo.git

net-analyzer/ike-scan: add libressl support

Package-Manager: portage-2.2.28
---

diff --git a/net-analyzer/ike-scan/ike-scan-1.9-r2.ebuild b/net-analyzer/ike-scan/ike-scan-1.9-r2.ebuild
new file mode 100644
index 000000000000..143c316977c5
--- /dev/null
+++ b/net-analyzer/ike-scan/ike-scan-1.9-r2.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+DESCRIPTION="A utility for finding, fingerprinting and testing IKE VPN servers"
+HOMEPAGE="http://www.nta-monitor.com/ike-scan/"
+SRC_URI="http://www.nta-monitor.com/ike-scan/download/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="libressl ssl"
+
+DEPEND="ssl? (
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+)"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	# Fix buffer overflow, bug #277556
+	sed \
+		-e "/MAXLINE/s:255:511:g" \
+		-i ike-scan.h || die
+}
+
+src_configure() {
+	# --disable-lookup prevents ike-scan from phoning home
+	# for more information, please see bug 157507
+	econf $(use_with ssl openssl) --disable-lookup
+}
+
+src_install() {
+	default
+	dodoc udp-backoff-fingerprinting-paper.txt
+}