From: Mart Raudsepp <leio@gentoo.org>
Date: Wed, 1 Jan 2020 15:06:18 +0000 (+0200)
Subject: media-libs/gstreamer: remove old
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=5922824dba45efe0c66d83487c0a355dd6a55c30;p=gentoo.git

media-libs/gstreamer: remove old

Package-Manager: Portage-2.3.79, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>
---

diff --git a/media-libs/gstreamer/Manifest b/media-libs/gstreamer/Manifest
index 2024b947ace4..231ffa797ccd 100644
--- a/media-libs/gstreamer/Manifest
+++ b/media-libs/gstreamer/Manifest
@@ -1,2 +1 @@
-DIST gstreamer-1.14.4.tar.xz 3264324 BLAKE2B d51febcd7c317964a09dadb4d3bd3ee7a60ac38bef28cdd7d42f49a7b710d6f6180ca7edee1765c8d146f7e3e852e93d0d5f69962089a653cfc3e6bd4ab42f89 SHA512 7ece9f01d40df7c8358482eac94536c5e15261e9568962008e2029e1ee1b3ebb220d2e4802ed1c81c40d897576fafe52234065e273724bfb4df3a3ddf2711abe
 DIST gstreamer-1.14.5.tar.xz 3268756 BLAKE2B 6ef5bdcb103b4d8fd581ae7342d6d467f4c6919610bdd620e4a531755347d8e3276a50f2e637045b9b97cbf7726495608437c180d37a1019ec8a79ab1bc4e4d6 SHA512 1a97ae17f8fff041db5e24d712d33c7116e408be1fabc2abd7b652b067b6ebe6c0943845a33a21335a5b4fa0a1ba178873158659f761f1e3aab04a969029c5d8
diff --git a/media-libs/gstreamer/gstreamer-1.14.4.ebuild b/media-libs/gstreamer/gstreamer-1.14.4.ebuild
deleted file mode 100644
index 4bcd587409bc..000000000000
--- a/media-libs/gstreamer/gstreamer-1.14.4.ebuild
+++ /dev/null
@@ -1,116 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit bash-completion-r1 multilib-minimal pax-utils
-
-DESCRIPTION="Open source multimedia framework"
-HOMEPAGE="https://gstreamer.freedesktop.org/"
-SRC_URI="https://${PN}.freedesktop.org/src/${PN}/${P}.tar.xz"
-
-LICENSE="LGPL-2+"
-SLOT="1.0"
-KEYWORDS="alpha amd64 arm arm64 ~hppa ia64 ~mips ppc ppc64 ~sh ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
-IUSE="+caps +introspection nls +orc test unwind"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	>=dev-libs/glib-2.40.0:2[${MULTILIB_USEDEP}]
-	caps? ( sys-libs/libcap[${MULTILIB_USEDEP}] )
-	introspection? ( >=dev-libs/gobject-introspection-1.31.1:= )
-	unwind? (
-		>=sys-libs/libunwind-1.2_rc1[${MULTILIB_USEDEP}]
-		dev-libs/elfutils[${MULTILIB_USEDEP}]
-	)
-	!<media-libs/gst-plugins-bad-1.13.1:1.0
-"
-DEPEND="${RDEPEND}
-	dev-util/glib-utils
-	>=dev-util/gtk-doc-am-1.12
-	sys-devel/bison
-	sys-devel/flex
-	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
-	nls? ( sys-devel/gettext )
-"
-# gtk-doc-am to install API docs
-
-PATCHES=(
-	"${FILESDIR}"/1.14-glib-2.60-tests-compat.patch
-)
-
-src_configure() {
-	if [[ ${CHOST} == *-interix* ]] ; then
-		export ac_cv_lib_dl_dladdr=no
-		export ac_cv_func_poll=no
-	fi
-	if [[ ${CHOST} == powerpc-apple-darwin* ]] ; then
-		# GCC groks this, but then refers to an implementation (___multi3,
-		# ___udivti3) that don't exist (at least I can't find it), so force
-		# this one to be off, such that we use 2x64bit emulation code.
-		export gst_cv_uint128_t=no
-	fi
-
-	multilib-minimal_src_configure
-}
-
-multilib_src_configure() {
-	local completiondir=$(get_bashcompdir)
-	# Set 'libexecdir' to ABI-specific location for the library spawns
-	# helpers from there.
-	# Disable static archives and examples to speed up build time
-	# Disable debug, as it only affects -g passing (debugging symbols), this must done through make.conf in gentoo
-	local myconf=(
-		--libexecdir="${EPREFIX}"/usr/$(get_libdir)
-		--disable-benchmarks
-		--disable-debug
-		--disable-examples
-		--disable-static
-		--disable-valgrind
-		--enable-check
-		$(use_with unwind)
-		$(use_with unwind dw)
-		$(multilib_native_use_enable introspection)
-		$(use_enable nls)
-		$(use_enable test tests)
-		--with-bash-completion-dir="${completiondir%/*}"
-		--with-package-name="GStreamer ebuild for Gentoo"
-		--with-package-origin="https://packages.gentoo.org/package/media-libs/gstreamer"
-	)
-
-	if use caps ; then
-		myconf+=( --with-ptp-helper-permissions=capabilities )
-	else
-		myconf+=(
-			--with-ptp-helper-permissions=setuid-root
-			--with-ptp-helper-setuid-user=nobody
-			--with-ptp-helper-setuid-group=nobody
-		)
-	fi
-
-	ECONF_SOURCE="${S}" econf "${myconf[@]}"
-
-	if multilib_is_native_abi; then
-		local x
-		for x in gst libs plugins; do
-			ln -s "${S}"/docs/${x}/html docs/${x}/html || die
-		done
-	fi
-}
-
-multilib_src_install() {
-	# can't do "default", we want to install docs in multilib_src_install_all
-	emake DESTDIR="${D}" install
-
-	# Needed for orc-using gst plugins on hardened/PaX systems, bug #421579
-	use orc && pax-mark -m "${ED}usr/$(get_libdir)/gstreamer-${SLOT}/gst-plugin-scanner"
-}
-
-multilib_src_install_all() {
-	DOCS="AUTHORS ChangeLog NEWS MAINTAINERS README RELEASE"
-	einstalldocs
-	find "${ED}" -name '*.la' -delete || die
-
-	# Needed for orc-using gst plugins on hardened/PaX systems, bug #421579
-	use orc && pax-mark -m "${ED}usr/bin/gst-launch-${SLOT}"
-}