From: Andreas K. Hüttel <dilfridge@gentoo.org>
Date: Mon, 21 May 2018 21:54:12 +0000 (+0200)
Subject: app-text/pdf2htmlEX: Add live ebuild
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=54964cde4b7b96f6611f3bfd9df533097d6249f1;p=gentoo.git

app-text/pdf2htmlEX: Add live ebuild

Package-Manager: Portage-2.3.38, Repoman-2.3.9
---

diff --git a/app-text/pdf2htmlEX/pdf2htmlEX-9999.ebuild b/app-text/pdf2htmlEX/pdf2htmlEX-9999.ebuild
new file mode 100644
index 000000000000..327250408f93
--- /dev/null
+++ b/app-text/pdf2htmlEX/pdf2htmlEX-9999.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils toolchain-funcs flag-o-matic versionator
+
+DESCRIPTION="A precise PDF to HTML converter (dilfridge fork)"
+HOMEPAGE="https://github.com/akhuettel/pdf2htmlEX"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/akhuettel/pdf2htmlEX.git"
+else
+	SRC_URI="https://dev.gentoo.org/~dilfridge/distfiles/${P}.tar.xz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE=""
+
+CDEPEND="
+	>=app-text/poppler-0.61.1:=[jpeg,png]
+	<app-text/poppler-0.64.0
+	app-text/poppler-data
+	~media-gfx/fontforge-20170731
+	media-libs/freetype
+	x11-libs/cairo[svg]
+"
+RDEPEND="${CDEPEND}
+"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig
+"
+
+pkg_pretend() {
+	local ver=6.4.0
+	local msg="${P} needs at least GCC ${ver} set to compile."
+	if [[ ${MERGE_TYPE} != binary ]]; then
+		if ! version_is_at_least ${ver} $(gcc-fullversion); then
+			die ${msg}
+		fi
+	fi
+}
+
+src_configure() {
+	append-cflags -no-pie
+	append-cxxflags -no-pie -fpermissive
+	cmake-utils_src_configure
+}