From: Michael Sterrett <mr_bones_@gentoo.org>
Date: Tue, 16 Feb 2016 00:53:23 +0000 (-0500)
Subject: games-strategy/s25rttr: clean old
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=4e27ce36d95bb0909d348172b5b824c6a4a5a4f6;p=gentoo.git

games-strategy/s25rttr: clean old

Package-Manager: portage-2.2.26
---

diff --git a/games-strategy/s25rttr/s25rttr-0.8.1.ebuild b/games-strategy/s25rttr/s25rttr-0.8.1.ebuild
deleted file mode 100644
index 202ecbc53324..000000000000
--- a/games-strategy/s25rttr/s25rttr-0.8.1.ebuild
+++ /dev/null
@@ -1,109 +0,0 @@
-# Copyright 1999-2015 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI=5
-inherit eutils cmake-utils gnome2-utils games
-
-DESCRIPTION="Open Source remake of The Settlers II game (needs original game files)"
-HOMEPAGE="http://www.siedler25.org/"
-# no upstream source tarball yet
-# https://bugs.launchpad.net/s25rttr/+bug/1069546
-SRC_URI="https://dev.gentoo.org/~hasufell/distfiles/${P}.tar.xz"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="amd64 x86"
-IUSE="debug glfw"
-
-RDEPEND="app-arch/bzip2
-	media-libs/libsamplerate
-	media-libs/libsdl[X,sound,opengl,video]
-	media-libs/libsndfile
-	media-libs/sdl-mixer[vorbis]
-	net-libs/miniupnpc
-	virtual/libiconv
-	virtual/opengl
-	glfw? ( <media-libs/glfw-3 )"
-DEPEND="${RDEPEND}
-	sys-devel/gettext"
-
-src_prepare() {
-	epatch "${FILESDIR}"/${P}-cmake.patch \
-		"${FILESDIR}"/${P}-soundconverter.patch \
-		"${FILESDIR}"/${P}-fpic.patch
-}
-
-src_configure() {
-	local arch
-	case ${ARCH} in
-		amd64)
-			arch="x86_64" ;;
-		x86)
-			arch="i386" ;;
-		*) die "Architecture ${ARCH} not yet supported" ;;
-	esac
-
-	local mycmakeargs=(
-		-DCOMPILEFOR="linux"
-		-DCOMPILEARCH="${arch}"
-		-DCMAKE_SKIP_RPATH=YES
-		-DPREFIX="${GAMES_PREFIX}"
-		-DBINDIR="${GAMES_BINDIR}"
-		-DDATADIR="${GAMES_DATADIR}"
-		-DLIBDIR="$(games_get_libdir)/${PN}"
-		-DDRIVERDIR="$(games_get_libdir)/${PN}"
-		-DGAMEDIR="~/.${PN}/S2"
-		$(cmake-utils_use_build glfw GLFW_DRIVER)
-	)
-
-	cmake-utils_src_configure
-}
-
-src_compile() {
-	# work around some relative paths (CMAKE_IN_SOURCE_BUILD not supported)
-	ln -s "${CMAKE_USE_DIR}"/RTTR "${CMAKE_BUILD_DIR}"/RTTR || die
-
-	cmake-utils_src_compile
-
-	mv "${CMAKE_USE_DIR}"/RTTR/{sound-convert,s-c_resample} "${T}"/ || die
-}
-
-src_install() {
-	cd "${CMAKE_BUILD_DIR}" || die
-
-	exeinto "$(games_get_libdir)"/${PN}
-	doexe "${T}"/{sound-convert,s-c_resample}
-	exeinto "$(games_get_libdir)"/${PN}/video
-	doexe driver/video/SDL/src/libvideoSDL.so
-	use glfw && doexe driver/video/GLFW/src/libvideoGLFW.so
-	exeinto "$(games_get_libdir)"/${PN}/audio
-	doexe driver/audio/SDL/src/libaudioSDL.so
-
-	insinto "${GAMES_DATADIR}"
-	doins -r "${CMAKE_USE_DIR}"/RTTR
-	dosym ./LSTS/splash.bmp "${GAMES_DATADIR}"/RTTR/splash.bmp
-
-	doicon -s 64 "${CMAKE_USE_DIR}"/debian/${PN}.png
-	dogamesbin src/s25client
-	make_desktop_entry "s25client" "Settlers RTTR" "${PN}"
-	dodoc RTTR/texte/{keyboardlayout.txt,readme.txt}
-
-	prepgamesdirs
-}
-
-pkg_preinst() {
-	games_pkg_preinst
-	gnome2_icon_savelist
-}
-
-pkg_postinst() {
-	games_pkg_postinst
-	elog "Copy your Settlers2 game files into ~/.${PN}/S2"
-
-	gnome2_icon_cache_update
-}
-
-pkg_postrm() {
-	gnome2_icon_cache_update
-}