From: Michael Mair-Keimberger <m.mairkeimberger@gmail.com>
Date: Mon, 11 Jun 2018 20:18:48 +0000 (+0200)
Subject: x11-plugins/wmapm: EAPI7, use HTTPS, improve ebuild
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=472aaceb5d67a86d31daa08c7976c61469952fdc;p=gentoo.git

x11-plugins/wmapm: EAPI7, use HTTPS, improve ebuild
---

diff --git a/x11-plugins/wmapm/wmapm-3.1-r2.ebuild b/x11-plugins/wmapm/wmapm-3.1-r2.ebuild
new file mode 100644
index 000000000000..6e795f7937f3
--- /dev/null
+++ b/x11-plugins/wmapm/wmapm-3.1-r2.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="WindowMaker DockApp: Battery/Power status monitor for laptops"
+HOMEPAGE="https://www.dockapps.net/wmapm"
+SRC_URI="https://www.dockapps.net/download/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE=""
+
+RDEPEND="x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXpm"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto"
+
+S="${WORKDIR}/${P}/${PN}"
+
+src_prepare() {
+	#Respect LDFLAGS, see bug #334747
+	sed -i 's/ -o wmapm/ ${LDFLAGS} -o wmapm/' "Makefile"
+	default
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)" COPTS="${CFLAGS}"
+}
+
+src_install() {
+	dobin wmapm
+	doman wmapm.1
+	dodoc ../{BUGS,CHANGES,HINTS,README,TODO}
+}