From: Henning Schild <henning@hennsch.de>
Date: Wed, 10 Jan 2018 08:42:14 +0000 (+1100)
Subject: www-apps/rutorrent: version bump to 9999
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=45e3a1375b6875ff76c73c66da84b6992ab8381b;p=gentoo.git

www-apps/rutorrent: version bump to 9999

taken from
https://github.com/doctaweeks/junkdrawer-overlay
with slight modification

Closes: https://github.com/gentoo/gentoo/pull/5322
Package-Manager: Portage-2.3.14, Repoman-2.3.6
---

diff --git a/www-apps/rutorrent/rutorrent-9999.ebuild b/www-apps/rutorrent/rutorrent-9999.ebuild
new file mode 100644
index 000000000000..28165b2caaa4
--- /dev/null
+++ b/www-apps/rutorrent/rutorrent-9999.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit webapp
+
+DESCRIPTION="ruTorrent is a front-end for the popular Bittorrent client rTorrent"
+HOMEPAGE="https://github.com/Novik/ruTorrent"
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Novik/ruTorrent.git"
+else
+	SRC_URI="https://github.com/Novik/ruTorrent/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~ppc ~x86"
+fi
+
+LICENSE="GPL-2"
+IUSE=""
+
+need_httpd_cgi
+
+DEPEND="
+	|| ( dev-lang/php[xml,gd] dev-lang/php[xml,gd-external] )
+"
+RDEPEND="virtual/httpd-php"
+
+pkg_setup() {
+	webapp_pkg_setup
+}
+
+src_prepare() {
+	default
+	find -name '\.gitignore' -type f -exec rm -rf {} \;
+	if [[ ${PV} == 9999 ]]; then
+		rm -rf .git
+	fi
+}
+
+src_install() {
+	webapp_src_preinst
+
+	insinto "${MY_HTDOCSDIR}"
+	doins -r .
+
+	chmod +x "${ED}${MY_HTDOCSDIR}"/plugins/*/*.sh \
+		"$ED${MY_HTDOCSDIR}"/php/test.sh || die "chmod failed"
+
+	webapp_serverowned "${MY_HTDOCSDIR}"/share
+	webapp_serverowned "${MY_HTDOCSDIR}"/share/settings
+	webapp_serverowned "${MY_HTDOCSDIR}"/share/torrents
+	webapp_serverowned "${MY_HTDOCSDIR}"/share/users
+
+	webapp_configfile "${MY_HTDOCSDIR}"/conf/.htaccess
+	webapp_configfile "${MY_HTDOCSDIR}"/conf/config.php
+	webapp_configfile "${MY_HTDOCSDIR}"/conf/access.ini
+	webapp_configfile "${MY_HTDOCSDIR}"/conf/plugins.ini
+	webapp_configfile "${MY_HTDOCSDIR}"/share/.htaccess
+
+	webapp_src_install
+}