From: Jeroen Roovers <jer@gentoo.org>
Date: Fri, 1 Feb 2019 09:36:39 +0000 (+0100)
Subject: app-text/pinfo: Fix installing /etc/pinforc in prefix
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=30e26b979f8c928eee6210c6a637a15b9a5b0b40;p=gentoo.git

app-text/pinfo: Fix installing /etc/pinforc in prefix

Patch by Susan Wilson. Thanks!

Package-Manager: Portage-2.3.59, Repoman-2.3.12
Fixes: https://bugs.gentoo.org/676992
Signed-off-by: Jeroen Roovers <jer@gentoo.org>
---

diff --git a/app-text/pinfo/pinfo-0.6.10-r7.ebuild b/app-text/pinfo/pinfo-0.6.10-r7.ebuild
new file mode 100644
index 000000000000..dc0428966984
--- /dev/null
+++ b/app-text/pinfo/pinfo-0.6.10-r7.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools flag-o-matic
+
+DESCRIPTION="Hypertext info and man viewer based on (n)curses"
+HOMEPAGE="http://pinfo.alioth.debian.org/"
+SRC_URI="https://alioth.debian.org/frs/download.php/3351/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="nls readline"
+
+RDEPEND="
+	sys-libs/ncurses:0=
+	sys-libs/readline:0=
+	nls? ( virtual/libintl )
+"
+
+DEPEND="
+	${RDEPEND}
+	sys-apps/texinfo
+	sys-devel/bison
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.6.9-as-needed.patch
+	"${FILESDIR}"/${PN}-0.6.9-GROFF_NO_SGR.patch
+	"${FILESDIR}"/${PN}-0.6.9-lzma-xz.patch
+	"${FILESDIR}"/${PN}-0.6.10-version.patch
+	"${FILESDIR}"/${PN}-0.6.10-info-suffix.patch
+	"${FILESDIR}"/${PN}-0.6.10-dir-file.patch
+	"${FILESDIR}"/${PN}-0.6.10-tinfo.patch
+	"${FILESDIR}"/${PN}-0.6.10-gettext-0.19.patch
+	"${FILESDIR}"/${PN}-0.6.10-ncurses-check.patch
+	"${FILESDIR}"/${PN}-0.6.10-libc-basename.patch
+	"${FILESDIR}"/${PN}-0.6.10-clearfilenameprefix.patch
+	"${FILESDIR}"/${PN}-0.6.10-gcc-7-inline.patch
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+
+	append-cflags -D_BSD_SOURCE -D_DEFAULT_SOURCE # sbrk()
+}
+
+src_configure() {
+	econf \
+		$(use_with readline) \
+		$(use_enable nls)
+}
+
+src_install() {
+	emake DESTDIR="${D}" sysconfdir="${EPREFIX}/etc" install
+}