From: Ulrich Müller <ulm@gentoo.org>
Date: Tue, 27 Aug 2019 10:18:04 +0000 (+0200)
Subject: app-editors/jed: Bump EAPI to 7.
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=125841110e82a2297aaf0015d85262706433fb34;p=gentoo.git

app-editors/jed: Bump EAPI to 7.

Package-Manager: Portage-2.3.73, Repoman-2.3.17
Signed-off-by: Ulrich Müller <ulm@gentoo.org>
---

diff --git a/app-editors/jed/jed-0.99.19-r1.ebuild b/app-editors/jed/jed-0.99.19-r1.ebuild
new file mode 100644
index 000000000000..ec91058ed134
--- /dev/null
+++ b/app-editors/jed/jed-0.99.19-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_P="${PN}-$(ver_rs 2 -)"
+DESCRIPTION="Console S-Lang-based editor"
+HOMEPAGE="http://www.jedsoft.org/jed/"
+SRC_URI="ftp://space.mit.edu/pub/davis/jed/v${PV%.*}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-macos"
+IUSE="X gpm xft"
+
+RDEPEND=">=sys-libs/slang-2
+	gpm? ( sys-libs/gpm )
+	X? (
+		x11-libs/libX11
+		xft? (
+			>=media-libs/freetype-2
+			x11-libs/libXft
+		)
+	)"
+DEPEND="${RDEPEND}
+	X? (
+		x11-libs/libXt
+		x11-base/xorg-proto
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	# replace IDE mode with EMACS mode
+	sed -i -e 's/\(_Jed_Default_Emulation = \).*/\1"emacs";/' \
+		lib/jed.conf || die
+	eapply_user
+}
+
+src_configure() {
+	econf \
+		$(use_enable gpm) \
+		$(use_enable xft) \
+		JED_ROOT="${EPREFIX}"/usr/share/jed
+}
+
+src_compile() {
+	emake
+	use X && emake xjed
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install
+
+	dodoc changes.txt INSTALL{,.unx} README
+	doinfo info/jed*
+
+	insinto /etc
+	doins lib/jed.conf
+}