From: Patrice Clement <monsieurp@gentoo.org>
Date: Sun, 8 Jan 2017 22:08:50 +0000 (+0100)
Subject: app-misc/vcp: EAPI 6 bump.
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=0b4a7192210595ac535424740926f7a4eea2100b;p=gentoo.git

app-misc/vcp: EAPI 6 bump.

Package-Manager: portage-2.3.0
---

diff --git a/app-misc/vcp/vcp-2.2-r2.ebuild b/app-misc/vcp/vcp-2.2-r2.ebuild
new file mode 100644
index 000000000000..506ddf1b2785
--- /dev/null
+++ b/app-misc/vcp/vcp-2.2-r2.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION="Copy files/directories in a curses interface"
+HOMEPAGE="http://members.iinet.net.au/~lynx/vcp/"
+SRC_URI="http://members.iinet.net.au/~lynx/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+
+DEPEND="sys-libs/ncurses:0="
+RDEPEND="${DEPEND}"
+
+DOCS=( Changelog README INSTALL )
+
+src_prepare() {
+	default
+	sed -i Makefile -e '/-o vcp/s|$(CFLAGS)|& $(LDFLAGS)|' || die "sed Makefile"
+}
+
+src_compile() {
+	filter-lfs-flags
+	emake CC="$(tc-getCC)"
+}
+
+src_install() {
+	dobin "${PN}"
+	doman "${PN}.1"
+	insinto /etc
+	newins "${PN}.conf.sample" "${PN}.conf"
+	einstalldocs
+}