dev-libs/ell: Added live ebuild

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

diff --git a/dev-libs/ell/ell-9999.ebuild b/dev-libs/ell/ell-9999.ebuild
new file mode 100644 (file)
index 0000000..6e917ad
--- /dev/null
+++ b/dev-libs/ell/ell-9999.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib-minimal
+
+DESCRIPTION="Embedded Linux Library provides core, low-level functionality for system daemons"
+HOMEPAGE="https://01.org/ell"
+if [[ "${PV}" == *9999 ]] ; then
+       inherit autotools git-r3
+       EGIT_REPO_URI="https://git.kernel.org/pub/scm/libs/ell/ell.git"
+else
+       SRC_URI="https://mirrors.edge.kernel.org/pub/linux/libs/${PN}/${P}.tar.xz"
+       KEYWORDS="~amd64 ~arm ~mips ~ppc ~ppc64 ~x86"
+fi
+LICENSE="LGPL-2.1"
+SLOT="0"
+
+IUSE="glib pie"
+
+RDEPEND="
+       glib? ( dev-libs/glib:2[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+       default
+       [[ "${PV}" == *9999 ]] && eautoreconf
+}
+
+multilib_src_configure() {
+       local myeconfargs=(
+               $(use_enable glib)
+               $(use_enable pie)
+       )
+       ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+       local DOCS=( ChangeLog README )
+       einstalldocs
+
+       find "${ED}" -name "*.la" -delete || die
+}