dev-util/edb-debugger: Initial commit bug #610798. Petros404

Package-Manager: portage-2.3.0

diff --git a/dev-util/edb-debugger/Manifest b/dev-util/edb-debugger/Manifest
new file mode 100644 (file)
index 0000000..1226fd7
--- /dev/null
+++ b/dev-util/edb-debugger/Manifest
@@ -0,0 +1 @@
+DIST edb-debugger-0.9.21.tgz 1042641 SHA256 2686619e1288152033d4c9c9a2568cb12841d3854bba8815c37ce77d3bd11706 SHA512 de921fa866da7d83efad92797bebcac3544ba1ffd5b3a015865b9bd554e8bc2e43539a9e4648517aff37f7d2497fdc4e1f6dc63df5cb0663012662626b1964f7 WHIRLPOOL 00c77e770c7fdc68644fcef732dc1c93ca6327f6543e80f9b628630ee6059a70bb51f4a290f73ae7502cfabad8f7eefca9a3e8762c778059e5eabeb439baed8b

diff --git a/dev-util/edb-debugger/edb-debugger-0.9.21.ebuild b/dev-util/edb-debugger/edb-debugger-0.9.21.ebuild
new file mode 100644 (file)
index 0000000..19de251
--- /dev/null
+++ b/dev-util/edb-debugger/edb-debugger-0.9.21.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils
+
+DESCRIPTION="edb is a cross platform x86/x86-64 debugger, inspired by Ollydbg"
+HOMEPAGE="https://github.com/eteran/edb-debugger"
+
+LICENSE="GPL-2+"
+IUSE="graphviz legacy-mem-write pax_kernel"
+SLOT="0"
+
+SRC_URI="https://github.com/eteran/edb-debugger/releases/download/${PV}/edb-debugger-${PV}.tgz"
+KEYWORDS="~amd64 ~x86"
+
+S="${WORKDIR}/edb-debugger-${PV}"
+
+RDEPEND="
+       >=dev-libs/capstone-3.0
+       graphviz? ( >=media-gfx/graphviz-2.38.0 )
+       dev-qt/qtwidgets:5
+       dev-qt/qtxml:5
+       dev-qt/qtxmlpatterns:5
+       dev-qt/qtnetwork:5
+       dev-qt/qtconcurrent:5
+       dev-qt/qtgui:5
+       dev-qt/qtcore:5
+       "
+DEPEND="
+       >=dev-libs/boost-1.35.0
+       virtual/pkgconfig
+       ${RDEPEND}"
+
+src_prepare(){
+       if ! use graphviz; then
+               sed -i '/pkg_check_modules(GRAPHVIZ/d' CMakeLists.txt || die
+       fi
+       cmake-utils_src_prepare
+}
+
+src_configure() {
+       mycmakeargs=(
+               -DCMAKE_INSTALL_PREFIX=/usr
+               -DQT_VERSION=Qt5
+       )
+       if use pax_kernel || use legacy-mem-write; then
+               mycmakeargs+=( -DASSUME_PROC_PID_MEM_WRITE_BROKEN=Yes )
+       else
+               mycmakeargs+=( -DASSUME_PROC_PID_MEM_WRITE_BROKEN=No )
+       fi
+
+       cmake-utils_src_configure
+}
+
+pkg_postinst() {
+       if use legacy-mem-write; then
+               ewarn "You really do not want to turn on legacy-mem-write unless you need it."
+               ewarn "Be sure to test without legacy-mem-write first and only enable if you actually need it."
+       else
+               ewarn
+               ewarn "If you notice that EDB doesn't work correctly, enable legacy-mem-write USE Flag"
+               ewarn "Please Report Bugs & Requests At: https://github.com/eteran/edb-debugger/issues"
+               ewarn
+       fi
+}

diff --git a/dev-util/edb-debugger/metadata.xml b/dev-util/edb-debugger/metadata.xml
new file mode 100644 (file)
index 0000000..626eba8
--- /dev/null
+++ b/dev-util/edb-debugger/metadata.xml
@@ -0,0 +1,18 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+        <maintainer type="person">
+                <email>petross404@gmail.com</email>
+                <name>Petros S</name>
+                <description>Proxied Maintainer</description>
+        </maintainer>
+        <maintainer type="project">
+                <email>proxy-maint@gentoo.org</email>
+                <name>Proxy Maintainers</name>
+        </maintainer>
+       <use>
+       <flag name="legacy-mem-write">Probe if writes to /proc/PID/mem are broken.</flag>
+       <flag name="graphviz">Add support for the Graphviz library</flag>
+       <flag name="pax_kernel">Enable building under a PaX enabled kernel</flag>
+       </use>
+</pkgmetadata>