net-libs/libsignon-glib: revision bump with various fixes

This introduces an introspection USE flag which eliminates an automagic
dependency.

The python USE flag requires the new introspection USE flag to be enabled,
as they are introspection bindings and build but do not run without the backing
introspection files.

This revision bump also corrects the python dependencies, prunes an unused
libtool file, and switches to EAPI 6.

Package-Manager: portage-2.3.0

diff --git a/net-libs/libsignon-glib/libsignon-glib-1.13-r1.ebuild b/net-libs/libsignon-glib/libsignon-glib-1.13-r1.ebuild
new file mode 100644 (file)
index 0000000..0ca692f
--- /dev/null
+++ b/net-libs/libsignon-glib/libsignon-glib-1.13-r1.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4,3_5} )
+inherit autotools eutils python-r1 vcs-snapshot xdg-utils
+
+DESCRIPTION="GLib binding for the D-Bus API provided by signond"
+HOMEPAGE="https://01.org/gsso/"
+SRC_URI="https://gitlab.com/accounts-sso/libsignon-glib/repository/archive.tar.gz?ref=VERSION_1.13 -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="LGPL-2.1"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc +introspection python test"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} python? ( introspection )"
+
+RDEPEND="
+       dev-libs/glib:2
+       net-libs/signond
+       introspection? ( dev-libs/gobject-introspection:= )
+       python? (
+               ${PYTHON_DEPS}
+               dev-python/pygobject:3[${PYTHON_USEDEP}]
+       )
+"
+DEPEND="${RDEPEND}
+       dev-util/gdbus-codegen
+       doc? ( dev-util/gtk-doc )
+"
+
+DOCS=( AUTHORS NEWS README )
+
+# needs more love
+RESTRICT="test"
+
+src_prepare() {
+       default
+
+       if ! use doc; then
+               epatch "${FILESDIR}/${PN}-1.12-doc-disable.patch"
+       fi
+
+       eautoreconf
+}
+
+src_configure() {
+       xdg_environment_reset
+
+       myconfigure() {
+               local myeconfargs=(
+                       $(use_enable debug)
+                       $(use_enable doc gtk-doc)
+                       $(use_enable introspection)
+                       $(use_enable python)
+                       $(use_enable test tests)
+               )
+
+               econf "${myeconfargs[@]}"
+       }
+
+       if use python; then
+               python_copy_sources
+               python_foreach_impl run_in_build_dir myconfigure
+       else
+               myconfigure
+       fi
+}
+
+src_compile() {
+       # fails to compile with more than one thread
+       MAKEOPTS="${MAKEOPTS} -j1"
+       default
+       if use python; then
+               python_foreach_impl run_in_build_dir default
+       fi
+}
+
+src_install() {
+       default
+       if use python; then
+               python_foreach_impl run_in_build_dir default
+       fi
+       prune_libtool_files
+}