sci-libs/pcl: bump to 1.9.1

Closes: https://bugs.gentoo.org/672536
Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Alexis Ballier <aballier@gentoo.org>

diff --git a/sci-libs/pcl/Manifest b/sci-libs/pcl/Manifest
index 21eb2ed022a5d3e562f79083e19a480f8f73789c..1e61e230c5aa71e2736a010ba9a493b198a2bd04 100644 (file)
--- a/sci-libs/pcl/Manifest
+++ b/sci-libs/pcl/Manifest
@@ -1 +1,2 @@
 DIST pcl-1.8.1.tar.gz 66787596 BLAKE2B d02439bc0c0b9cf179f5840822dcad9b3cd128c53325d5f1a5b67e0153c8b4c5150cd65763e17d2c28f91325eb9ae33d9fa6e673a17681b05d19c46eaf0bdb9d SHA512 9e7c87fb750a176712f08d215a906012c9e8174b687bbc8c08fa65de083b4468951bd8017b10409015d5eff0fc343885d2aae5c340346118b1a251af7bdd5cd7
+DIST pcl-1.9.1.tar.gz 67158067 BLAKE2B 472422930e08feba11f42a2df49d68e0c55484744e0649164b113dc3b654188e598b1c0a55f1b75680150090749b00378ae0f70b35b1695a7914a16be7415bf7 SHA512 ca95028c23861ac2df0fa7e18fdd0202255cb2e49ab714325eb36c35289442c6eedbf489e6f9f232b30fa2a93eff4c9619f8a14d3fdfe58f353a4a6e26206bdf

diff --git a/sci-libs/pcl/pcl-1.9.1.ebuild b/sci-libs/pcl/pcl-1.9.1.ebuild
new file mode 100644 (file)
index 0000000..737d110
--- /dev/null
+++ b/sci-libs/pcl/pcl-1.9.1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+SCM=""
+if [ "${PV#9999}" != "${PV}" ] ; then
+       SCM="git-r3"
+       EGIT_REPO_URI="https://github.com/PointCloudLibrary/pcl"
+fi
+
+inherit ${SCM} cmake-utils multilib
+
+if [ "${PV#9999}" != "${PV}" ] ; then
+       KEYWORDS=""
+       SRC_URI=""
+else
+       KEYWORDS="~amd64 ~arm"
+       SRC_URI="https://github.com/PointCloudLibrary/pcl/archive/${P}.tar.gz"
+       S="${WORKDIR}/${PN}-${P}"
+fi
+
+HOMEPAGE="http://pointclouds.org/"
+DESCRIPTION="2D/3D image and point cloud processing"
+LICENSE="BSD"
+SLOT="0/1.9"
+IUSE="cuda doc opengl openni openni2 pcap png +qhull qt5 usb vtk cpu_flags_x86_sse test tutorials"
+
+RDEPEND="
+       >=sci-libs/flann-1.7.1
+       dev-libs/boost:=[threads]
+       dev-cpp/eigen:3
+       opengl? ( virtual/opengl media-libs/freeglut )
+       openni? ( dev-libs/OpenNI )
+       openni2? ( dev-libs/OpenNI2 )
+       pcap? ( net-libs/libpcap )
+       png? ( media-libs/libpng:0= )
+       qhull? ( media-libs/qhull )
+       qt5? (
+               dev-qt/qtgui:5
+               dev-qt/qtcore:5
+               dev-qt/qtconcurrent:5
+               dev-qt/qtopengl:5
+       )
+       usb? ( virtual/libusb:1 )
+       vtk? ( >=sci-libs/vtk-5.6:=[imaging,rendering] )
+       cuda? ( >=dev-util/nvidia-cuda-toolkit-4 )
+"
+DEPEND="${RDEPEND}
+       !!dev-cpp/metslib
+       doc? ( app-doc/doxygen )
+       tutorials? ( dev-python/sphinx dev-python/sphinxcontrib-doxylink )
+       test? ( >=dev-cpp/gtest-1.6.0 )
+       virtual/pkgconfig"
+
+REQUIRED_USE="
+       openni? ( usb )
+       openni2? ( usb )
+       tutorials? ( doc )
+"
+
+src_configure() {
+       local mycmakeargs=(
+               "-DLIB_INSTALL_DIR=$(get_libdir)"
+               "-DWITH_CUDA=$(usex cuda TRUE FALSE)"
+               "-DWITH_LIBUSB=$(usex usb TRUE FALSE)"
+               "-DWITH_OPENGL=$(usex opengl TRUE FALSE)"
+               "-DWITH_PNG=$(usex png TRUE FALSE)"
+               "-DWITH_QHULL=$(usex qhull TRUE FALSE)"
+               "-DWITH_QT=$(usex qt5 TRUE FALSE)"
+               "-DWITH_VTK=$(usex vtk TRUE FALSE)"
+               "-DWITH_PCAP=$(usex pcap TRUE FALSE)"
+               "-DWITH_OPENNI=$(usex openni TRUE FALSE)"
+               "-DBUILD_OPENNI=$(usex openni TRUE FALSE)"
+               "-DWITH_OPENNI2=$(usex openni2 TRUE FALSE)"
+               "-DBUILD_OPENNI2=$(usex openni2 TRUE FALSE)"
+               "-DPCL_ENABLE_SSE=$(usex cpu_flags_x86_sse TRUE FALSE)"
+               "-DWITH_DOCS=$(usex doc TRUE FALSE)"
+               "-DWITH_TUTORIALS=$(usex tutorials TRUE FALSE)"
+               "-DBUILD_TESTS=$(usex test TRUE FALSE)"
+       )
+       cmake-utils_src_configure
+}

diff --git a/sci-libs/pcl/pcl-9999.ebuild b/sci-libs/pcl/pcl-9999.ebuild
index 9475d9da70369bc6e8f83b15e909c40d5712a27c..737d110e2cfe1e05c55aa2dac2633a1c0fb9c37b 100644 (file)
--- a/sci-libs/pcl/pcl-9999.ebuild
+++ b/sci-libs/pcl/pcl-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=5
@@ -23,7 +23,7 @@ fi
 HOMEPAGE="http://pointclouds.org/"
 DESCRIPTION="2D/3D image and point cloud processing"
 LICENSE="BSD"
-SLOT="0/1.8"
+SLOT="0/1.9"
 IUSE="cuda doc opengl openni openni2 pcap png +qhull qt5 usb vtk cpu_flags_x86_sse test tutorials"
 
 RDEPEND="