app-portage/gemato: Add a live ebuild for multiprocessing branch

Add a separate ebuild for multiprocessing branch and keep it p.masked
due to the known hangs.  Hopefully it will help testing and finding
a proper solution to that.

Bug: https://bugs.gentoo.org/647964

diff --git a/app-portage/gemato/gemato-9999m.ebuild b/app-portage/gemato/gemato-9999m.ebuild
new file mode 100644 (file)
index 0000000..5761670
--- /dev/null
+++ b/app-portage/gemato/gemato-9999m.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+# pyblake2 & pysha3 are broken with pypy3
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6,3_7} pypy )
+PYTHON_REQ_USE='threads(+)'
+inherit distutils-r1 git-r3
+
+DESCRIPTION="Stand-alone Manifest generation & verification tool"
+HOMEPAGE="https://github.com/mgorny/gemato"
+SRC_URI=""
+EGIT_REPO_URI="https://github.com/mgorny/gemato.git"
+EGIT_BRANCH="multiprocessing"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS=""
+IUSE="+blake2 bzip2 +gpg lzma sha3 test tools"
+
+MODULE_RDEPEND="
+       blake2? ( $(python_gen_cond_dep 'dev-python/pyblake2[${PYTHON_USEDEP}]' python{2_7,3_4,3_5} pypy{,3}) )
+       bzip2? ( $(python_gen_cond_dep 'dev-python/bz2file[${PYTHON_USEDEP}]' python2_7 pypy) )
+       gpg? ( app-crypt/gnupg )
+       lzma? ( $(python_gen_cond_dep 'dev-python/backports-lzma[${PYTHON_USEDEP}]' python2_7 pypy) )
+       sha3? ( $(python_gen_cond_dep 'dev-python/pysha3[${PYTHON_USEDEP}]' python{2_7,3_4,3_5} pypy{,3}) )"
+
+RDEPEND="${MODULE_RDEPEND}
+       dev-python/setuptools[${PYTHON_USEDEP}]"
+DEPEND=">=dev-python/setuptools-34[${PYTHON_USEDEP}]
+       test? ( ${MODULE_RDEPEND} )"
+
+python_test() {
+       esetup.py test
+}
+
+python_install_all() {
+       distutils-r1_python_install_all
+
+       if use tools; then
+               exeinto /usr/share/gemato
+               doexe utils/*.{bash,py}
+       fi
+}
+
+pkg_postinst() {
+       elog "The multiprocessing support in gemato may cause the process to hang."
+       elog "Please see https://bugs.gentoo.org/647964 for more details."
+}

diff --git a/profiles/package.mask b/profiles/package.mask
index 548fd1b1c1856229c9cc878b5a605cc5d76e3384..a9edadcf52ac594569f089e501783a412b5a94ed 100644 (file)
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -29,6 +29,12 @@
 
 #--- END OF EXAMPLES ---
 
+# Michał Górny <mgorny@gentoo.org> (01 Aug 2018)
+# Multiprocessing versions of gemato.  They are known to hang on some
+# users, so let's keep them masked until somebody figures out what's
+# wrong.  Bug #647964.
+~app-portage/gemato-9999m
+
 # Joonas Niilola <juippis@gmail.com> (31 Jul 2018)
 # Old and obsolete. Merged into one EFL package since 1.18 release. 
 # Removal in ~30 days. Bug #662510