app-emulation/runc: Update snapshot

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Manuel Rüger <mrueg@gentoo.org>

diff --git a/app-emulation/runc/Manifest b/app-emulation/runc/Manifest
index 1c9690abec386153f07e41f0bd74ff6b1bebca56..5d90a7a3cddfb75f4908293b7b699f268b35bf1c 100644 (file)
--- a/app-emulation/runc/Manifest
+++ b/app-emulation/runc/Manifest
@@ -1,2 +1,3 @@
 DIST runc-1.0.0_rc5_p20180509.tar.gz 1185576 BLAKE2B b56f9c185c061f51a1fd81c19d378b06c71d06c6eddcbc1c946b234814eb469ea4af37bf42ef3889e4d37bc430e69d0a563281b13055f855f1bc15935531fe28 SHA512 9a55bdb8e39830f46cceff48970b7688139927552e3d268b9ef4a6e640ffc3d95164b99c5b05d07d295bedc2ea22daf6062fd520df1548d78b1d481fd928f1e3
 DIST runc-1.0.0_rc6_p20181203.tar.gz 1202869 BLAKE2B 5b5808fc65f3725e5cc22794c5ff6c5eba6016110358b0f60dd3378df2e5b64afb5631e5652f45e9721838dd02745b8c5a88abfcd244de202196ac16bfccd5a7 SHA512 ec3d3fec773f2f9df714b0813efb110e21e328634e0b4ae77f323a892d0327aea5d4b6f9ae2a549aa06fda5b27431f4514fd663c7033dc170ca1a03627931f9d
+DIST runc-1.0.0_rc6_p20190216.tar.gz 1663903 BLAKE2B d6094e85f1d35e1dcc7aed94adffe384f651953568345a9f6edb7ef17b24e25d8572ba84a23326c134c2dae28e1d62d0715a8bd6d949d7ef5cbc4cbc6af2f635 SHA512 e3d61506b44f05dfbad2e07d917c8408edea54c87a472ceb109e2ba2a1685b26f1407c2fe7660d416b60fc2583414af09567bcb8b3c95bc14f725d120373337c

diff --git a/app-emulation/runc/runc-1.0.0_rc6_p20190216.ebuild b/app-emulation/runc/runc-1.0.0_rc6_p20190216.ebuild
new file mode 100644 (file)
index 0000000..e411018
--- /dev/null
+++ b/app-emulation/runc/runc-1.0.0_rc6_p20190216.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+EGO_PN="github.com/opencontainers/${PN}"
+
+if [[ ${PV} == *9999 ]]; then
+       inherit golang-build golang-vcs
+else
+       MY_PV="${PV/_/-}"
+       RUNC_COMMIT="2b18fe1d885ee5083ef9f0838fee39b62d653e30" # Change this when you update the ebuild
+       SRC_URI="https://${EGO_PN}/archive/${RUNC_COMMIT}.tar.gz -> ${P}.tar.gz"
+       KEYWORDS="~amd64 ~arm ~arm64 ~ppc64"
+       inherit golang-build golang-vcs-snapshot
+fi
+
+DESCRIPTION="runc container cli tools"
+HOMEPAGE="http://runc.io"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="+ambient apparmor hardened +kmem +seccomp"
+
+RDEPEND="
+       apparmor? ( sys-libs/libapparmor )
+       seccomp? ( sys-libs/libseccomp )
+       !app-emulation/docker-runc
+"
+
+src_prepare() {
+       pushd src/${EGO_PN}
+       default
+       sed -i -e "/^GIT_BRANCH/d"\
+               -e "/^GIT_BRANCH_CLEAN/d"\
+               -e "/^COMMIT_NO/d"\
+               -e "s/COMMIT :=.*/COMMIT := ${RUNC_COMMIT}/"\
+               Makefile || die
+       popd || die
+}
+
+src_compile() {
+       # Taken from app-emulation/docker-1.7.0-r1
+       export CGO_CFLAGS="-I${ROOT}/usr/include"
+       export CGO_LDFLAGS="$(usex hardened '-fno-PIC ' '')
+               -L${ROOT}/usr/$(get_libdir)"
+
+       # build up optional flags
+       local options=(
+               $(usex ambient 'ambient' '')
+               $(usex apparmor 'apparmor' '')
+               $(usex seccomp 'seccomp' '')
+               $(usex kmem '' 'nokmem')
+       )
+
+       GOPATH="${S}" emake BUILDTAGS="${options[*]}" -C src/${EGO_PN}
+}
+
+src_install() {
+       pushd src/${EGO_PN} || die
+       dobin runc
+       dodoc README.md PRINCIPLES.md
+       popd || die
+}