dev-lisp/cl-unicode: add from lisp overlay

Package-Manager: portage-2.2.20.1

diff --git a/dev-lisp/cl-unicode/Manifest b/dev-lisp/cl-unicode/Manifest
new file mode 100644 (file)
index 0000000..ca8b513
--- /dev/null
+++ b/dev-lisp/cl-unicode/Manifest
@@ -0,0 +1 @@
+DIST cl-unicode-0.1.5.tar.gz 485666 SHA256 9e9f1dda5133c3c94e09f638fec01410254c0020b89cc7342416d8ed1d377ee3 SHA512 0b66c0e711f7e37423aa638b43017adff648189a32032702b082dff140b2255847a15572a20f21e6f82a2e8cbd547f7f99bf9176e4fa464aa1d938575d8a2390 WHIRLPOOL e0b973416ff76f4e66b203ea5545c782a4bf59dccbbc7f1d26c6a78870efa31a4fe0b2e7eae17be25f49efc06272201ce9472fbb9e22d5332de8014aea1bc14c

diff --git a/dev-lisp/cl-unicode/cl-unicode-0.1.5.ebuild b/dev-lisp/cl-unicode/cl-unicode-0.1.5.ebuild
new file mode 100644 (file)
index 0000000..acc5def
--- /dev/null
+++ b/dev-lisp/cl-unicode/cl-unicode-0.1.5.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit common-lisp-3
+
+MY_P="v${PV}"
+
+DESCRIPTION="A library which provides Common Lisp implementations with knowledge about Unicode characters."
+HOMEPAGE="http://weitz.de/cl-unicode/"
+SRC_URI="https://github.com/edicl/${PN}/archive/${MY_P}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE=""
+
+DEPEND="dev-lisp/flexi-streams"
+RDEPEND="dev-lisp/cl-ppcre"
+
+COMMONLISPS="sbcl clisp clozurecl cmucl ecls openmcl"
+
+find-lisp-impl() {
+       for lisp in ${COMMONLISPS} ; do
+               [[ "$(best_version dev-lisp/${lisp})" ]] && echo "${lisp}" && return
+       done
+       die "No CommonLisp implementation found"
+}
+
+src_compile() {
+       # cl-unicode builds parts of its source code automatically the first time it
+       # is compiled, so we compile it here.
+       local lispimpl=$(find-lisp-impl)
+       local initclunicode="(progn (push \"${S}/\" asdf:*central-registry*) (require :${PN}))"
+       common-lisp-export-impl-args "${lispimpl}"
+       ${lispimpl} ${CL_EVAL} "${initclunicode}"
+}
+
+src_install() {
+       common-lisp-install-sources *.lisp test/
+       common-lisp-install-sources -t all build/
+       common-lisp-install-asdf
+       dodoc CHANGELOG
+       dohtml doc/index.html
+}

diff --git a/dev-lisp/cl-unicode/metadata.xml b/dev-lisp/cl-unicode/metadata.xml
new file mode 100644 (file)
index 0000000..433fe2c
--- /dev/null
+++ b/dev-lisp/cl-unicode/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+       <herd>common-lisp</herd>
+       <longdescription>
+               CL-UNICODE is a library which provides Common Lisp implementations
+               with knowledge about Unicode characters including their name, their
+               general category, the scripts and blocks they belong to, their
+               numerical value, and several other properties. It also provides the
+               ability to replace the standard syntax for reading Lisp characters
+               with one that is Unicode-aware and is used to enhance CL-PPCRE with
+               Unicode properties.
+       </longdescription>
+</pkgmetadata>