media-sound/jack2: add live ebuild

Package-Manager: Portage-2.3.16, Repoman-2.3.6

diff --git a/media-sound/jack2/jack2-1.9.11_rc1-r1.ebuild b/media-sound/jack2/jack2-1.9.11_rc1-r1.ebuild
index 087957d1728b593539edc61f62d84cc86f39a811..0823bd254c5ab33d0cd873948fc30254407b0666 100644 (file)
--- a/media-sound/jack2/jack2-1.9.11_rc1-r1.ebuild
+++ b/media-sound/jack2/jack2-1.9.11_rc1-r1.ebuild
@@ -10,7 +10,7 @@ inherit eutils python-single-r1 waf-utils multilib-minimal
 DESCRIPTION="Jackdmp jack implemention for multi-processor machine"
 HOMEPAGE="http://jackaudio.org/"
 
-if [[ "${PV}" = "2.9999" ]]; then
+if [[ "${PV}" = "9999" ]]; then
        inherit git-r3
        EGIT_REPO_URI="https://github.com/jackaudio/${PN}.git"
        KEYWORDS=""

diff --git a/media-sound/jack2/jack2-1.9.11_rc1.ebuild b/media-sound/jack2/jack2-1.9.11_rc1.ebuild
index ca8206fee86933f60fae95d995c2be162aebb652..fdf94f71e711bde8b504ab2fc1f1ca2ab0b1f266 100644 (file)
--- a/media-sound/jack2/jack2-1.9.11_rc1.ebuild
+++ b/media-sound/jack2/jack2-1.9.11_rc1.ebuild
@@ -10,7 +10,7 @@ inherit eutils python-single-r1 waf-utils multilib-minimal
 DESCRIPTION="Jackdmp jack implemention for multi-processor machine"
 HOMEPAGE="http://jackaudio.org/"
 
-if [[ "${PV}" = "2.9999" ]]; then
+if [[ "${PV}" = "9999" ]]; then
        inherit git-r3
        EGIT_REPO_URI="https://github.com/jackaudio/${PN}.git"
        KEYWORDS=""

diff --git a/media-sound/jack2/jack2-9999.ebuild b/media-sound/jack2/jack2-9999.ebuild
new file mode 100644 (file)
index 0000000..0823bd2
--- /dev/null
+++ b/media-sound/jack2/jack2-9999.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="threads(+)"
+inherit eutils python-single-r1 waf-utils multilib-minimal
+
+DESCRIPTION="Jackdmp jack implemention for multi-processor machine"
+HOMEPAGE="http://jackaudio.org/"
+
+if [[ "${PV}" = "9999" ]]; then
+       inherit git-r3
+       EGIT_REPO_URI="https://github.com/jackaudio/${PN}.git"
+       KEYWORDS=""
+else
+       MY_PV="${PV/_rc/-RC}"
+       MY_P="${PN}-${MY_PV}"
+       S="${WORKDIR}/${MY_P}"
+       SRC_URI="https://github.com/jackaudio/jack2/releases/download/v${MY_PV}/${MY_P}.tar.gz"
+       KEYWORDS="~amd64 ~ppc ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="2"
+IUSE="alsa celt dbus doc opus pam classic sndfile libsamplerate readline"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+CDEPEND="media-libs/libsamplerate
+       media-libs/libsndfile
+       sys-libs/readline:0=
+       ${PYTHON_DEPS}
+       alsa? ( media-libs/alsa-lib[${MULTILIB_USEDEP}] )
+       celt? ( media-libs/celt:0[${MULTILIB_USEDEP}] )
+       dbus? (
+               dev-libs/expat[${MULTILIB_USEDEP}]
+               sys-apps/dbus[${MULTILIB_USEDEP}]
+       )
+       opus? ( media-libs/opus[custom-modes,${MULTILIB_USEDEP}] )"
+DEPEND="${CDEPEND}
+       virtual/pkgconfig
+       doc? ( app-doc/doxygen )"
+RDEPEND="${CDEPEND}
+       dbus? ( dev-python/dbus-python[${PYTHON_USEDEP}] )
+       pam? ( sys-auth/realtime-base )
+       !media-sound/jack-audio-connection-kit:0"
+
+DOCS=( ChangeLog README README_NETJACK2 TODO )
+
+src_prepare() {
+       default
+       multilib_copy_sources
+}
+
+multilib_src_configure() {
+       local mywafconfargs=(
+               --htmldir=/usr/share/doc/${PF}/html
+               $(usex dbus --dbus "")
+               $(usex classic --classic "")
+               --alsa=$(usex alsa yes no)
+               --celt=$(usex celt yes no)
+               --doxygen=$(multilib_native_usex doc yes no)
+               --firewire=no
+               --freebob=no
+               --iio=no
+               --opus=$(usex opus yes no)
+               --portaudio=no
+               --readline=$(multilib_native_usex readline yes no)
+               --samplerate=$(multilib_native_usex libsamplerate yes no)
+               --sndfile=$(multilib_native_usex sndfile yes no)
+               --winmme=no
+       )
+
+       waf-utils_src_configure ${mywafconfargs[@]}
+}
+
+multilib_src_compile() {
+       WAF_BINARY="${BUILD_DIR}"/waf waf-utils_src_compile
+}
+
+multilib_src_install() {
+       WAF_BINARY="${BUILD_DIR}"/waf waf-utils_src_install
+}
+
+multilib_src_install_all() {
+       python_fix_shebang "${ED}"
+}