dev-libs/swaylock: Add 9999 live version

Package-Manager: Portage-2.3.59, Repoman-2.3.12
Signed-off-by: Niccolò Scatena <speedjack95@gmail.com>
Signed-off-by: Aaron Bauman <bman@gentoo.org>

diff --git a/dev-libs/swaylock/swaylock-9999.ebuild b/dev-libs/swaylock/swaylock-9999.ebuild
new file mode 100644 (file)
index 0000000..85539fb
--- /dev/null
+++ b/dev-libs/swaylock/swaylock-9999.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit fcaps meson
+
+DESCRIPTION="Screen locker for Wayland"
+HOMEPAGE="https://github.com/swaywm/swaylock"
+
+if [[ ${PV} == 9999 ]]; then
+       inherit git-r3
+       EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
+else
+       SRC_URI="https://github.com/swaywm/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+       KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="fish-completion +gdk-pixbuf +man +pam zsh-completion"
+
+DEPEND="
+       dev-libs/wayland
+       x11-libs/cairo
+       x11-libs/libxkbcommon
+       gdk-pixbuf? ( x11-libs/gdk-pixbuf:2 )
+       pam? ( virtual/pam )
+"
+RDEPEND="
+       ${DEPEND}
+       !<=dev-libs/sway-1.0_beta2[swaylock]
+"
+BDEPEND="
+       >=dev-libs/wayland-protocols-1.14
+       virtual/pkgconfig
+       man? ( app-text/scdoc )
+"
+
+src_configure() {
+       local emesonargs=(
+               -Dman-pages=$(usex man enabled disabled)
+               -Dpam=$(usex pam enabled disabled)
+               -Dgdk-pixbuf=$(usex gdk-pixbuf enabled disabled)
+               $(meson_use fish-completion fish-completions)
+               $(meson_use zsh-completion zsh-completions)
+               "-Dbash-completions=true"
+               "-Dwerror=false"
+       )
+       if [[ ${PV} != 9999 ]]; then
+               emesonargs+=("-Dswaylock-version=${PV}")
+       fi
+
+       meson_src_configure
+}
+
+pkg_postinst() {
+       if ! use pam; then
+               fcaps cap_sys_admin usr/bin/swaylock
+       fi
+}