app-vim/pydiction: port to python-r1.

This package is slightly more complicated so let's use the python-r1 class
instead.

Gentoo-Bug: https://bugs.gentoo.org/615910

Package-Manager: Portage-2.3.6, Repoman-2.3.1

diff --git a/app-vim/pydiction/pydiction-1.2.3-r2.ebuild b/app-vim/pydiction/pydiction-1.2.3-r2.ebuild
new file mode 100644 (file)
index 0000000..b014415
--- /dev/null
+++ b/app-vim/pydiction/pydiction-1.2.3-r2.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit vim-plugin python-r1
+
+DESCRIPTION="vim plugin: tab-complete your Python code"
+HOMEPAGE="https://rkulla.github.io/pydiction/"
+SRC_URI="https://dev.gentoo.org/~monsieurp/packages/${P}.zip"
+
+LICENSE="vim"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="app-arch/unzip"
+RDEPEND="${PYTHON_DEPS}"
+
+S="${WORKDIR}/${PN}-master"
+
+src_install() {
+       # Rename pydiction script.
+       mv "${PN}.py" "${PN}" || die
+
+       # We're going to remove those files in a second 
+       # otherwise they're installed by Portage.
+       local pyfiles=( complete-dict "${PN}" )
+       insinto "/usr/share/${P}"
+       doins complete-dict
+
+       # pydiction is treated a singular script that lives on its own.
+       python_foreach_impl python_doscript "${PN}"
+       rm -v "${pyfiles[@]}" || die
+
+       vim-plugin_src_install
+}