sci-libs/p4est: version bump to 2.2

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Matthias Maier <tamiko@gentoo.org>

diff --git a/sci-libs/p4est/Manifest b/sci-libs/p4est/Manifest
index 0ce540d27caaf841dab671ce5a1097364415a583..d8b401c263375ee72596ab88100f13d7f5774885 100644 (file)
--- a/sci-libs/p4est/Manifest
+++ b/sci-libs/p4est/Manifest
@@ -1,6 +1,8 @@
 DIST libsc-1.0.tar.gz 257930 BLAKE2B b67ee98d8a31dcd09af70783a253b7289657c51e345c59b6551ab8be3a2067ce20d75c3f6323f4113501d57baf31d95c5a40b025c77f37a693616ae2bb118266 SHA512 bf5af600e9cbd4038b1bd40c88776b21be5d474e34f9aacf287b890d262a22dc50ca27982c2eb9adba9735c8d9bb1fc31de2a27b24cdab534e3b2f610d76db7d
 DIST libsc-1.1.tar.gz 263643 BLAKE2B 827c0e01154983dd309301c6ecfa380d3489b5b764f131c2df2554b002a6c726a44272963cef4b4a853af5fb4c9ba98c77b01e107fc555432317662d985de2a9 SHA512 a3d8bea406a1987e68e88dd587aebe28c796f2a5bddfc381b34b5eb1448e0ac23889cc6f97fc1e4010289f83996180db42cbb001d0518360349b993dd37d4579
 DIST libsc-2.0.tar.gz 296392 BLAKE2B b5e1ca5cf6802ed38c32db5e7a77aec2fc636d88f2562314088dc16d13a0dccd24706276b05f8ddd70bc3769270a378c0089873fb2a21ebc93d6ca2622d7a58e SHA512 e4cfe42a1c1fe17412e1ffb6ebebe1f760861a7fb707a6f8fd01cdebda96b166ee05e7ff034f3b9e30de5e9baa82c9a2cebe93d40772dbd206603321de40559c
+DIST libsc-2.2.tar.gz 311542 BLAKE2B 0879be69208f0964d73cc297a64b158ad88344e876a90dd4bd39c80fc0cf8237f4551cb684dee36e08068fa04644b887ec56230335a9984363055c1248aa6185 SHA512 97953794fdeb985bedb1dc9378f10ed4824446c63762d7813aced3309c2d6b27368c91fecb22587dccdf8b3b42aaaba9e782b739086cf542570360795897ac14
 DIST p4est-1.0.tar.gz 695027 BLAKE2B 1b4c21e0ada4928da4fbf94e80e123ad39a1b4701f6019d0e49073b68c90662a277302a07cad22bb1d71a72a47cde8e1cbbfd4475dd7542bcee1c0474bb4addf SHA512 781240bbca2779f4076c310575ad99e8b526ecf6a3da8b7b5f096615bbfb570dd0556e607797715b69c95c6dd73baf837f1c632be763efae835941107f1fe3df
 DIST p4est-1.1.tar.gz 1241423 BLAKE2B 3bb767f062a204abee4af64351981609c818c9b1f6bc5fa738161f706e5c9aebe208a4fc76010a2a05d6936070952e938b6ee632bd3ccc6676776fd60d451ef8 SHA512 11eb576a16a4cc959eff8894d6cb11d8bae092951be9cf9d71b538825bdf675af7fd77d79505b9e896ec1810c1f8e9391447a79263c6d2e33fef780e97d07f29
 DIST p4est-2.0.tar.gz 1296762 BLAKE2B 1d755ec72905da069b9c91182a437c59107189402eb26444cf7fc1755b81bdbfad9aa25802720df401e8d434e5ac67e68b1d7dd5bf312f881017925498ad7514 SHA512 05f8a95ad431bd36fd3e48ca9360de0f90d1af7dfc77601cd46766898a9bc82b9157e22bdb6135e7003f59c7ecc4cd9ad34b89de25ba3c6f11a86d46cac8592c
+DIST p4est-2.2.tar.gz 1323529 BLAKE2B 262cb8d1ceff1329a71fd302b12c1650e9c099e72a9a93b4abef5822b16a28af0ee1ce9a338c524c2077d4bff83e607e9346f5bb1c660aa9afa8241bb631a637 SHA512 8475e0b6ab1225b22e7538c9c9b227f9aef86f78adf0706065a05f4682618f8f5d3878c18c11b8b13b3912e1de95f40b0ef5f5f5d217c02196993ac07f085299

diff --git a/sci-libs/p4est/p4est-2.0.ebuild b/sci-libs/p4est/p4est-2.0.ebuild
index a54c8b564e3ea396885b2db5fd8de90f5d551988..62bc613a26027f3a95884b49fc2848a76ae8bdd4 100644 (file)
--- a/sci-libs/p4est/p4est-2.0.ebuild
+++ b/sci-libs/p4est/p4est-2.0.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6

diff --git a/sci-libs/p4est/p4est-2.2.ebuild b/sci-libs/p4est/p4est-2.2.ebuild
new file mode 100644 (file)
index 0000000..8cd883f
--- /dev/null
+++ b/sci-libs/p4est/p4est-2.2.ebuild
@@ -0,0 +1,120 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# The build system currently fails with everything newer than 1.11.
+WANT_AUTOMAKE=1.11
+
+inherit autotools toolchain-funcs eutils
+
+DESCRIPTION="Scalable Algorithms for Parallel Adaptive Mesh Refinement on Forests of Octrees"
+HOMEPAGE="http://www.p4est.org/"
+
+if [[ ${PV} = *9999* ]]; then
+       inherit git-r3
+       EGIT_REPO_URI="https://github.com/cburstedde/${PN}.git"
+       EGIT_BRANCH="develop"
+       SRC_URI=""
+       KEYWORDS=""
+else
+       SRC_URI="
+               https://github.com/cburstedde/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+               https://github.com/cburstedde/libsc/archive/v${PV}.tar.gz -> libsc-${PV}.tar.gz"
+       KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2+"
+SLOT="0"
+
+# TODO petsc
+IUSE="debug doc examples mpi openmp romio static-libs threads +vtk-binary"
+REQUIRED_USE="romio? ( mpi )"
+
+RDEPEND="
+       ~sci-libs/libsc-${PV}[mpi=,openmp=,romio=,static-libs=,threads=]
+       dev-lang/lua:*
+       sys-apps/util-linux
+       virtual/blas
+       virtual/lapack
+       mpi? ( virtual/mpi[romio=] )"
+
+DEPEND="
+       ${RDEPEND}
+       sys-devel/automake:1.11
+       virtual/pkgconfig"
+
+DOCS=( AUTHORS NEWS README )
+
+pkg_pretend() {
+       if [[ ${MERGE_TYPE} != "binary" ]] && use openmp; then
+               tc-has-openmp || \
+                       die "Please select an openmp capable compiler like gcc[openmp]"
+       fi
+}
+
+src_prepare() {
+       default
+
+       # Inject libsc to get  all parts of the build system...
+       if ! [[ ${PV} = *9999* ]]; then
+               rmdir "${S}/sc" || die "rmdir failed"
+               mv "${WORKDIR}/libsc-${PV}" "${S}/sc" || die "mv failed"
+       fi
+
+       # Inject a version number into the build system
+       echo "${PV}" > ${S}/.tarball-version
+
+       AT_M4DIR="${WORKDIR}/${P}/config ${WORKDIR}/${P}/sc/config"
+       eautoreconf
+
+       sed -i \
+               "s/P4EST_SC_DIR\/etc/P4EST_SC_DIR\/share\/libsc/" \
+               "${S}"/configure || die "sed failed"
+
+       sed -i \
+               "s/libsc\.la/libsc\.so/" \
+               "${S}"/configure || die "sed failed"
+
+}
+
+src_configure() {
+       # avoid underlinkage
+       LDFLAGS="${LDFLAGS} -lsc"
+
+       local myeconfargs=(
+               $(use_enable debug)
+               $(use_enable mpi)
+               $(use_enable openmp)
+               $(use_enable romio mpiio)
+               $(use_enable static-libs static)
+               $(use_enable threads pthread)
+               $(use_enable vtk-binary)
+               --with-blas="$($(tc-getPKG_CONFIG) --libs blas)"
+               --with-lapack="$($(tc-getPKG_CONFIG) --libs lapack)"
+               --with-sc="${EPREFIX}/usr"
+       )
+       econf "${myeconfargs[@]}"
+}
+
+src_install() {
+       default
+
+       use doc && dodoc -r doc/*
+
+       if use examples
+       then
+               docinto examples
+               dodoc -r example/*
+               docompress -x /usr/share/doc/${PF}/examples
+       else
+               # Remove compiled example binaries in case of -examples:
+               rm -r "${ED}"/usr/bin || die "rm failed"
+       fi
+
+       # Fix wrong installation paths:
+       dodir /usr/share/p4est
+       mv "${ED}"/usr/share/data "${ED}"/usr/share/p4est/data || die "mv failed"
+       mv "${ED}"/etc/* "${ED}"/usr/share/p4est || die "mv failed"
+       rmdir "${ED}"/etc/ || die "rmdir failed"
+}