media-video/baka-mplayer: fix mpv >=0.23.0 support

Signed-off-by: Christopher Steward <cstew764@gmail.com>
Package-Manager: Portage-2.3.79, Repoman-2.3.16
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

diff --git a/media-video/baka-mplayer/baka-mplayer-2.0.4-r1.ebuild b/media-video/baka-mplayer/baka-mplayer-2.0.4-r1.ebuild
new file mode 100644 (file)
index 0000000..e131863
--- /dev/null
+++ b/media-video/baka-mplayer/baka-mplayer-2.0.4-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit qmake-utils
+
+DESCRIPTION="Cross-platform libmpv-based multimedia player with uncluttered design"
+HOMEPAGE="http://bakamplayer.u8sand.net/"
+SRC_URI="https://github.com/u8sand/Baka-MPlayer/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+BDEPEND="
+       dev-qt/linguist-tools:5
+       virtual/pkgconfig
+"
+RDEPEND="
+       dev-qt/qtcore:5
+       dev-qt/qtgui:5
+       dev-qt/qtnetwork:5
+       dev-qt/qtsvg:5
+       dev-qt/qtwidgets:5
+       dev-qt/qtx11extras:5
+       media-video/mpv[libmpv]
+       x11-libs/libX11"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/Baka-MPlayer-${PV}"
+
+PATCHES=( "${FILESDIR}/${P}-gcc5.patch" "${FILESDIR}/${P}-mpv23.patch" )
+
+src_prepare() {
+       default
+       # no need to install license
+       sed -e '/^INSTALLS/s:license::' -i src/Baka-MPlayer.pro || die
+       # put manual in our docdir
+       sed -e '/^manual.path/s:'${PN}':'${PF}':' -i src/Baka-MPlayer.pro || die
+}
+
+src_configure() {
+       eqmake5 \
+               INSTROOT="${D}" \
+               CONFIG+=install_translations \
+               lrelease="$(qt5_get_bindir)"/lrelease \
+               lupdate="$(qt5_get_bindir)"/lupdate \
+               src/Baka-MPlayer.pro
+}

diff --git a/media-video/baka-mplayer/files/baka-mplayer-2.0.4-mpv23.patch b/media-video/baka-mplayer/files/baka-mplayer-2.0.4-mpv23.patch
new file mode 100644 (file)
index 0000000..ef5551c
--- /dev/null
+++ b/media-video/baka-mplayer/files/baka-mplayer-2.0.4-mpv23.patch
@@ -0,0 +1,13 @@
+diff --git a/src/mpvhandler.cpp b/src/mpvhandler.cpp
+index 7ba06e4..b9ccbeb 100644
+--- a/src/mpvhandler.cpp
++++ b/src/mpvhandler.cpp
+@@ -675,7 +675,7 @@ void MpvHandler::LoadFileInfo()
+     fileInfo.media_title = mpv_get_property_string(mpv, "media-title");
+     // get length
+     double len;
+-    mpv_get_property(mpv, "length", MPV_FORMAT_DOUBLE, &len);
++    mpv_get_property(mpv, "duration", MPV_FORMAT_DOUBLE, &len);
+     fileInfo.length                  = (int)len;
+ 
+     LoadTracks();