sys-kernel/gentoo-kernel-bin: New package

-bin variant for sys-kernel/gentoo-kernel.

Signed-off-by: Michał Górny <mgorny@gentoo.org>

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
new file mode 100644 (file)
index 0000000..b593aaa
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -0,0 +1,4 @@
+DIST gentoo-kernel-5.4.10-1.amd64.xpak 64967384 BLAKE2B b182bf880cac1dd244848bb15a61a0bca7a6a910a4953af4012512f9bbe0313fd8f4358a75edfb1d883801bdc8289f42675efbba6479201421b3b616e937f20d SHA512 621fdf3b357e61cd3b41d545841ec2073303165a52d5b9b1b51d36c81529ffa15a71b955456967de71d7e91e51c175c3c9c85e2826aba2cdf02fbce6b4edb1ac
+DIST gentoo-kernel-5.4.10-1.x86.xpak 56394306 BLAKE2B 18a3139333844e749f278a46ee979a21704513792558ae07257207afa47a7879e6cf83269d37ca2cd1f3838277f9478ff172c778a3c0d5506191c944523dadba SHA512 c4289fccd37d8959752862ec9aa94faf1261474a5658c19cd90ed559fb5813743675129989f74a0a6ad6fd184dd9c0fea39153de7c671b902ce048cb23776292
+DIST tinycorelinux-10.1-amd64.qcow2 16842752 BLAKE2B e013e76503c335739a9623c0901ca791937a0e6b177854535cadec1e2c2cd2df588283ed3128cf652595f32264fbfe5b3bd3a8c97665fd4da344e308535be366 SHA512 c3aeb20ff8769da9211694b7f701907cc7ae7582cdfad2c2fdc008d97ebcbd9dc08245b4e8f8450e1cb304bd705345a11fe79f901a47979fee91443841d55641
+DIST tinycorelinux-10.1-x86.qcow2 14876672 BLAKE2B 3c760eb7438b13261e52ecfaa33a53649ced95f1ab40aae52134b8cdc31a16d7aa0d6a6dd716e268ed148e9d77a10b7c700b141b61d70c82d271ffe88e8e2a3c SHA512 9964538dc42f232a11949f74b61d46422ea5da3bdc253a217119bd0b8a750c40fd2da0b07157067be9ac0226472614f210a1248114df0d331df390979867a895

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.10.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.10.ebuild
new file mode 100644 (file)
index 0000000..6537031
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.10.ebuild
@@ -0,0 +1,54 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install
+
+MY_P=${P/-bin/}-1
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+       amd64? (
+               https://dev.gentoo.org/~mgorny/binpkg/amd64/kernel/sys-kernel/gentoo-kernel/${MY_P}.xpak
+                       -> ${MY_P}.amd64.xpak
+       )
+       x86? (
+               https://dev.gentoo.org/~mgorny/binpkg/x86/kernel/sys-kernel/gentoo-kernel/${MY_P}.xpak
+                       -> ${MY_P}.x86.xpak
+       )"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+       !sys-kernel/gentoo-kernel:${SLOT}
+       !sys-kernel/vanilla-kernel:${SLOT}
+       !sys-kernel/vanilla-kernel-bin:${SLOT}"
+
+QA_PREBUILT='*'
+
+pkg_pretend() {
+       mount-boot_pkg_pretend
+
+       ewarn "This is an experimental package.  The built kernel and/or initramfs"
+       ewarn "may not work at all or fail with your bootloader configuration.  Please"
+       ewarn "make sure to keep a backup kernel available before testing it."
+}
+
+src_unpack() {
+       ebegin "Unpacking ${MY_P}.${ARCH}.xpak"
+       tar -x < <(xz -c -d --single-stream "${DISTDIR}/${MY_P}.${ARCH}.xpak")
+       eend ${?} || die "Unpacking ${MY_P} failed"
+}
+
+src_test() {
+       kernel-install_test "${PV}" \
+               "${WORKDIR}/usr/src/linux-${PV}/$(kernel-install_get_image_path)" \
+               "lib/modules/${PV}"
+}
+
+src_install() {
+       mv * "${ED}" || die
+}

diff --git a/sys-kernel/gentoo-kernel-bin/metadata.xml b/sys-kernel/gentoo-kernel-bin/metadata.xml
new file mode 100644 (file)
index 0000000..b0b959a
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+       <maintainer type="project">
+               <email>dist-kernel@gentoo.org</email>
+               <name>Distribution Kernel Project</name>
+       </maintainer>
+       <use>
+               <flag name='initramfs'>Build initramfs along with the kernel.</flag>
+       </use>
+</pkgmetadata>