x11-misc/virtualgl: 2.6.1 version bump

Closes: https://bugs.gentoo.org/show_bug.cgi?id=674072
Package-Manager: Portage-2.3.55, Repoman-2.3.12
Signed-off-by: Craig Andrews <candrews@gentoo.org>

diff --git a/x11-misc/virtualgl/Manifest b/x11-misc/virtualgl/Manifest
index 02e239a09cf96a75facea9eb87fd73079d6d31b0..bde00332663d177b2ecf6886f1cf029ed692e6e9 100644 (file)
--- a/x11-misc/virtualgl/Manifest
+++ b/x11-misc/virtualgl/Manifest
@@ -1 +1,2 @@
 DIST VirtualGL-2.5.2.tar.gz 1172965 BLAKE2B 2aac9db4fdbec49c5251f9ba85fda81efd5025891a124991e9787e9bf869b054e419c6c377c0dcf5988a1785c16159c12a4c45d5d7419f3d6c17a09316dfd7e6 SHA512 a3156f663c03e611a98a083bb12bea47820cdadc9f064e20431fddec55aae560f09b133f5254a24d7da01b64be2672d27713d7f6605eaca2d9d83090a070fafd
+DIST VirtualGL-2.6.1.tar.gz 1278335 BLAKE2B 62abb082eb8c82fecff33dd5b5036ebaead99b837cf0dc42581790863f09814858fd7a23a479c0c4ac5e59a4cc99af58903016a5109a6636191ce98d6da3d0bd SHA512 36580e55e11ba3e93945d62e865fe0b63ecd5aa1ee3889fb4d0940c68da06737fff4689a77638f5c8c57dbc9d020ba821bdec9aa2f6b2f0f144b18f1c3d8c5e5

diff --git a/x11-misc/virtualgl/virtualgl-2.6.1.ebuild b/x11-misc/virtualgl/virtualgl-2.6.1.ebuild
new file mode 100644 (file)
index 0000000..05ef6a7
--- /dev/null
+++ b/x11-misc/virtualgl/virtualgl-2.6.1.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit cmake-multilib flag-o-matic multilib systemd
+
+if [[ ${PV} == *9999 ]] ; then
+       EGIT_REPO_URI="https://github.com/VirtualGL/${PN}.git"
+       inherit git-r3
+else
+       MY_PN="VirtualGL"
+       MY_P="${MY_PN}-${PV}"
+       S="${WORKDIR}/${MY_P}"
+       SRC_URI="mirror://sourceforge/project/${PN}/${PV}/${MY_P}.tar.gz"
+       KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+DESCRIPTION="Run OpenGL applications remotely with full 3D hardware acceleration"
+HOMEPAGE="https://www.virtualgl.org/"
+
+SLOT="0"
+LICENSE="LGPL-2.1 wxWinLL-3.1 FLTK"
+IUSE="libressl ssl"
+
+RDEPEND="
+       ssl? (
+               !libressl? ( dev-libs/openssl:0=[${MULTILIB_USEDEP}] )
+               libressl? ( dev-libs/libressl:0=[${MULTILIB_USEDEP}] )
+       )
+       media-libs/libjpeg-turbo[${MULTILIB_USEDEP}]
+       x11-libs/libX11[${MULTILIB_USEDEP}]
+       x11-libs/libXext[${MULTILIB_USEDEP}]
+       x11-libs/libXv[${MULTILIB_USEDEP}]
+       virtual/glu[${MULTILIB_USEDEP}]
+       virtual/opengl[${MULTILIB_USEDEP}]
+       amd64? ( abi_x86_32? (
+               >=media-libs/libjpeg-turbo-1.3.0-r3[abi_x86_32]
+               >=x11-libs/libX11-1.6.2[abi_x86_32]
+               >=x11-libs/libXext-1.3.2[abi_x86_32]
+               >=x11-libs/libXv-1.0.10[abi_x86_32]
+               >=virtual/glu-9.0-r1[abi_x86_32]
+               >=virtual/opengl-7.0-r1[abi_x86_32]
+       ) )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+       # Use /var/lib, bug #428122
+       sed -e "s#/etc/opt#/var/lib#g" -i doc/unixconfig.txt doc/index.html doc/advancedopengl.txt \
+               server/vglrun.in server/vglgenkey server/vglserver_config || die
+
+       cmake-utils_src_prepare
+}
+
+src_configure() {
+       # Completely breaks steam/wine for discrete graphics otherwise
+       # see https://github.com/VirtualGL/virtualgl/issues/16
+       append-ldflags "-Wl,--no-as-needed"
+
+       abi_configure() {
+               local mycmakeargs=(
+                       -DVGL_USESSL="$(usex ssl)"
+                       -DCMAKE_INSTALL_DOCDIR=/usr/share/doc/"${PF}"
+                       -DTJPEG_INCLUDE_DIR=/usr/include
+                       -DCMAKE_INSTALL_LIBDIR=/usr/$(get_libdir)
+                       -DTJPEG_LIBRARY=/usr/$(get_libdir)/libturbojpeg.so
+                       -DCMAKE_LIBRARY_PATH=/usr/$(get_libdir)
+               )
+               cmake-utils_src_configure
+       }
+       multilib_parallel_foreach_abi abi_configure
+}
+
+src_install() {
+       cmake-multilib_src_install
+
+       # Make config dir
+       dodir /var/lib/VirtualGL
+       fowners root:video /var/lib/VirtualGL
+       fperms 0750 /var/lib/VirtualGL
+       newinitd "${FILESDIR}/vgl.initd-r3" vgl
+       newconfd "${FILESDIR}/vgl.confd-r2" vgl
+
+       exeinto /usr/libexec
+       doexe "${FILESDIR}/vgl-helper.sh"
+       systemd_dounit "${FILESDIR}/vgl.service"
+
+       # Rename glxinfo to vglxinfo to avoid conflict with x11-apps/mesa-progs
+       mv "${D}"/usr/bin/{,v}glxinfo || die
+
+       # Remove license files, bug 536284
+       rm "${D}"/usr/share/doc/${PF}/{LGPL.txt*,LICENSE*} || die
+}