dev-python/nbformat: Version bump to 4.1.0, Bump to EAPI=6

Package-Manager: portage-2.2.28
Closes: https://github.com/gentoo/gentoo/pull/2128

Signed-off-by: David Seifert <soap@gentoo.org>

diff --git a/dev-python/nbformat/Manifest b/dev-python/nbformat/Manifest
index f866283e2153f90d52db2487efe66b50c54450f3..4cc9092065f9cb207a7ec1260ded95680f8b32c7 100644 (file)
--- a/dev-python/nbformat/Manifest
+++ b/dev-python/nbformat/Manifest
@@ -1 +1,2 @@
 DIST nbformat-4.0.1.tar.gz 105767 SHA256 5261c957589b9dfcd387c338d59375162ba9ca82c69e378961a1f4e641285db5 SHA512 f73e8cffc61825aa8b7b0ef3b842cba51baf2cdf0c5d0035e2e7cb51f71c6c819f09201367a3b342c2736492dee1e78c519961aaea8f2cc4b5e69a1545085d2a WHIRLPOOL 9b08003c456e00c529b7bf8e786d57a583e53e5a1e7e9eb4c3cc492c5b1d60e76579c9102e6c56749d546a9a124d475687d4ec1d71e0f3634698d5e30499db93
+DIST nbformat-4.1.0.tar.gz 108264 SHA256 dbf6c0ed0cb7c5a7184536368f1dd1ada2d48fd6f016e0f9e9b69236e28c0857 SHA512 606d8aa786fdbe8fe6d12d9a13886a49043b096a86ad180556f65f226d5031c98f6c80b4319de09292f2f17ed9e3a5038828c94a7306ed2abd78976e30fc08d4 WHIRLPOOL f01d3431fb007b12bbd892181781d87a700c01a28f1bf5308f4ae0f5c5dd63c768e926964848a3a21b6bd34e8d6d2b6c3d962b4dee1f034a387e45d2c3741a2e

diff --git a/dev-python/nbformat/nbformat-4.1.0.ebuild b/dev-python/nbformat/nbformat-4.1.0.ebuild
new file mode 100644 (file)
index 0000000..32fd6f3
--- /dev/null
+++ b/dev-python/nbformat/nbformat-4.1.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+PYTHON_REQ_USE='sqlite'
+
+inherit distutils-r1
+
+DESCRIPTION="Reference implementation of the Jupyter Notebook format"
+HOMEPAGE="http://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+       >=dev-python/jsonschema-2.4.0[${PYTHON_USEDEP}]
+       dev-python/ipython_genutils[${PYTHON_USEDEP}]
+       dev-python/traitlets[${PYTHON_USEDEP}]
+       dev-python/jupyter_core[${PYTHON_USEDEP}]
+       "
+DEPEND="${RDEPEND}
+       doc? (
+               dev-python/sphinx[${PYTHON_USEDEP}]
+               dev-python/numpydoc[${PYTHON_USEDEP}]
+       )
+       test? (
+               dev-python/nose[${PYTHON_USEDEP}]
+               dev-python/coverage[${PYTHON_USEDEP}]
+       )
+       "
+
+python_prepare_all() {
+       # Prevent un-needed download during build
+       if use doc; then
+               sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/conf.py || die
+       fi
+
+       distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+       use doc && emake -C docs html
+}
+
+python_test() {
+       distutils_install_for_testing
+       cd "${TEST_DIR}"/lib || die
+       nosetests --with-coverage --cover-package=nbformat nbformat || die
+}
+
+python_install_all() {
+       use doc && HTML_DOCS=( docs/_build/html/. )
+       distutils-r1_python_install_all
+}