app-emacs/semi: Version bump.

Bug: https://bugs.gentoo.org/688560
Signed-off-by: Markus Oehme <markus@jonglieren-jena.de>
[ulm@gentoo.org: EAPI 7 bump, minor cleanup]
Package-Manager: Portage-2.3.67, Repoman-2.3.14
Signed-off-by: Ulrich Müller <ulm@gentoo.org>

diff --git a/app-emacs/semi/Manifest b/app-emacs/semi/Manifest
index 73743402f2aa7786289a1f1a8d6ba2a29bef8ac4..936ec5cf4e47dfcf85cf4fdc8e80983f623c92cf 100644 (file)
--- a/app-emacs/semi/Manifest
+++ b/app-emacs/semi/Manifest
@@ -1 +1,2 @@
 DIST semi-1.14.6.tar.gz 142549 BLAKE2B e417b305ad814b2a23fad4fd37057395efb47bdb61778aa167149eda4277cda47dc81148821d9e4ad3225a858c77f781a6565c3e49747d78882b9401fd5fbac1 SHA512 1011271c58414f4ca23da079f16f273b408643e0d9f4961db321b65c1ed9a7d4ca66a7d7cb5b0c9fa2b4904fa992c9188858de6131180ee30132d3cadaeef33f
+DIST semi-1.14.7_p20190517.tar.gz 152636 BLAKE2B a22b1f9a5de0a695de2d8e342ca313af05c12a1c0b597890d926496e9ce240e3329365700f91e6268cf399976ec067163ac8197c7a643e499d70851501f63798 SHA512 d25c940fdd0a048d21079d905ae91521a1f1247b8f78145baeba24c994c0d5b30985a76c909a793f82f6253b323fb4699bbf059ea48037bb49ae92505b0c6d18

diff --git a/app-emacs/semi/semi-1.14.7_p20190517.ebuild b/app-emacs/semi/semi-1.14.7_p20190517.ebuild
new file mode 100644 (file)
index 0000000..0641b83
--- /dev/null
+++ b/app-emacs/semi/semi-1.14.7_p20190517.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit elisp
+
+DESCRIPTION="A library to provide MIME feature for GNU Emacs"
+HOMEPAGE="https://github.com/wanderlust/semi"
+GITHUB_SHA1="4cf114c95fb49ad75eb6916f678b45b04bad8122"
+SRC_URI="${HOMEPAGE}/archive/${GITHUB_SHA1}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="l10n_ja"
+
+DEPEND=">=app-emacs/apel-10.8
+       >=app-emacs/flim-1.14.9"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${PN}-${GITHUB_SHA1}"
+ELISP_PATCHES="${PN}-info.patch"
+SITEFILE="65${PN}-gentoo.el"
+
+src_compile() {
+       emake PREFIX="${ED}"/usr \
+               LISPDIR="${ED}/${SITELISP}" \
+               VERSION_SPECIFIC_LISPDIR="${ED}/${SITELISP}"
+
+       ${EMACS} ${EMACSFLAGS} --visit mime-ui-en.texi -f texi2info || die
+       if use l10n_ja; then
+               ${EMACS} ${EMACSFLAGS} \
+                       --eval "(set-default-coding-systems 'iso-2022-jp)" \
+                       --visit mime-ui-ja.texi -f texi2info || die
+       fi
+}
+
+src_install() {
+       emake PREFIX="${ED}/usr" \
+               LISPDIR="${ED}/${SITELISP}" \
+               VERSION_SPECIFIC_LISPDIR="${ED}/${SITELISP}" install
+
+       elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+
+       doinfo mime-ui-en.info
+       dodoc README.en ChangeLog VERSION NEWS
+       if use l10n_ja; then
+               doinfo mime-ui-ja.info
+               dodoc README.ja
+       fi
+}