app-admin/supervisor: EAPI=6, fix deps, remove obsolete comments.

Package-Manager: portage-2.3.2
Closes: https://github.com/gentoo/gentoo/pull/2978

Signed-off-by: Patrice Clement <monsieurp@gentoo.org>

diff --git a/app-admin/supervisor/supervisor-3.3.1-r1.ebuild b/app-admin/supervisor/supervisor-3.3.1-r1.ebuild
new file mode 100644 (file)
index 0000000..06fe66a
--- /dev/null
+++ b/app-admin/supervisor/supervisor-3.3.1-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )    # py2 only
+# xml.etree.ElementTree module required.
+PYTHON_REQ_USE="xml"
+
+inherit distutils-r1
+
+MY_PV="${PV/_beta/b}"
+
+DESCRIPTION="A system for controlling process state under UNIX"
+HOMEPAGE="http://supervisord.org/ https://pypi.python.org/pypi/supervisor"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${PN}-${MY_PV}.tar.gz"
+
+LICENSE="repoze ZPL BSD HPND GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+       dev-python/meld3[${PYTHON_USEDEP}]
+"
+DEPEND="
+       dev-python/setuptools[${PYTHON_USEDEP}]
+       doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+       test? (
+               ${RDEPEND}
+               dev-python/mock[${PYTHON_USEDEP}]
+       )
+"
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+python_compile_all() {
+       use doc && emake -C docs html
+}
+
+python_test() {
+       esetup.py test
+}
+
+python_install_all() {
+       newinitd "${FILESDIR}/init.d-r1" supervisord
+       newconfd "${FILESDIR}/conf.d" supervisord
+       use doc && local HTML_DOCS=( docs/.build/html/. )
+       distutils-r1_python_install_all
+}