sys-apps/bleachbit: version bump to 1.17.

Package-Manager: Portage-2.3.3, Repoman-2.3.1
Closes: https://github.com/gentoo/gentoo/pull/3966

diff --git a/sys-apps/bleachbit/Manifest b/sys-apps/bleachbit/Manifest
index e780ce8a13e5915da138ed09b70775819338ccbc..af53a7625b44c02c5489b08a6abaea403a64c9f0 100644 (file)
--- a/sys-apps/bleachbit/Manifest
+++ b/sys-apps/bleachbit/Manifest
@@ -1 +1,2 @@
 DIST bleachbit-1.12.tar.bz2 396838 SHA256 55188debde6ccb9d83ebf5bb9f8c821c616fa0dfe309779d3d87059c04b1a8f4 SHA512 b9c13a75b86eebbedaf928394714ac4d7847b8d53d345a4884acee68cd9c46ff1d5f4108479d7695109bad03c0fcdbb6f89e77d8794a60697fd5c6acdb34530c WHIRLPOOL e0df98dec3948eb6e8035911e82988a14876f07828e58e8badb4042b921e57d544bf060cb542fbd66e68b7c5652d3f9f08dbec2c9ae8a30ecb6df9431aae5d4b
+DIST bleachbit-1.17.tar.gz 867671 SHA256 fe76f43d7cc1347ca6fba1902b35ced454d7a0b45a6ac983d8b63987d4e94fa0 SHA512 c1d7d266e7baef532a9826ce1a0fb8cd247136a335c3236ba7cf6e4f7af4420e4f0f424fb98579c5433ebd55138860657a3fad3ad56ed4f4a3f8163526a73e95 WHIRLPOOL f06b0ac02d80a0dd8cd3f343b60a8af46abad5d6e96cc716d9e6b32539e9deb56574ffeb99285b3b7f1e16987b869275935cfae9b61e42708f176f1e1f9597b6

diff --git a/sys-apps/bleachbit/bleachbit-1.17.ebuild b/sys-apps/bleachbit/bleachbit-1.17.ebuild
new file mode 100644 (file)
index 0000000..997d4a6
--- /dev/null
+++ b/sys-apps/bleachbit/bleachbit-1.17.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PLOCALES="ar ast be bg bn bs ca cs da de el en_AU en_CA en_GB eo es et eu \
+fa fi fo fr gl he hi hr hu hy ia id it ja ko ku ky lt lv ms my nb nds nl nn \
+pl pt pt_BR ro ru se si sk sl sq sr sv ta te th tr ug uk uz vi zh_CN zh_TW"
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1 eutils l10n
+
+DESCRIPTION="Clean junk to free disk space and to maintain privacy"
+HOMEPAGE="https://www.bleachbit.org"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+gtk nls"
+
+RDEPEND="
+       dev-python/notify-python[$PYTHON_USEDEP]
+       gtk? ( dev-python/pygtk:2[$PYTHON_USEDEP] )"
+
+DEPEND="${RDEPEND}
+       nls? ( sys-devel/gettext )"
+
+DOCS=( README.md )
+
+python_prepare_all() {
+       rem_locale() {
+               rm "po/${1}.po" || die "removing of ${1}.po failed"
+       }
+
+       l10n_find_plocales_changes po "" ".po"
+       l10n_for_each_disabled_locale_do rem_locale
+
+       # choose correct Python implementation, bug #465254
+       sed -i -e 's/python/$(PYTHON)/g' po/Makefile || die
+
+       distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+       use nls && emake -C po
+}
+
+python_install_all() {
+       distutils-r1_python_install_all
+       use nls && emake -C po DESTDIR="${D}" install
+
+       # https://bugs.gentoo.org/388999
+       insinto /usr/share/${PN}/cleaners
+       doins cleaners/*.xml
+
+       newbin ${PN}.py ${PN}
+       python_replicate_script "${D}/usr/bin/${PN}"
+
+       doicon ${PN}.png
+       domenu ${PN}.desktop
+}