media-video/luvcview: Fix deps (#529284), install .desktop file

Package-Manager: Portage-2.3.38, Repoman-2.3.9

diff --git a/media-video/luvcview/luvcview-0.2.6-r1.ebuild b/media-video/luvcview/luvcview-0.2.6-r1.ebuild
new file mode 100644 (file)
index 0000000..34f1275
--- /dev/null
+++ b/media-video/luvcview/luvcview-0.2.6-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit desktop toolchain-funcs
+
+PATCH_LEVEL="4"
+
+DESCRIPTION="USB Video Class grabber"
+HOMEPAGE="https://packages.qa.debian.org/l/luvcview.html"
+SRC_URI="mirror://debian/pool/main/l/${PN}/${PN}_${PV}.orig.tar.gz
+       mirror://debian/pool/main/l/${PN}/${PN}_${PV}-${PATCH_LEVEL}.diff.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+       media-libs/libsdl
+       media-libs/libv4l
+       x11-libs/libX11
+"
+DEPEND="${RDEPEND}
+       virtual/pkgconfig
+"
+
+src_prepare() {
+       default
+       eapply "${WORKDIR}"/${PN}_${PV}-${PATCH_LEVEL}.diff
+       eapply debian/patches/*.patch
+       sed -i -e 's:videodev.h:videodev2.h:' *.{c,h} || die
+       sed -i -e 's:-O2::' Makefile || die
+}
+
+src_compile() {
+       emake CC="$(tc-getCC) ${LDFLAGS}"
+}
+
+src_install() {
+       dobin luvcview
+       doman debian/luvcview.1
+       dodoc Changelog README ToDo
+       make_desktop_entry ${PN}
+}