x11-wm/xpra: Version bump and invoce xdg_pkg_post* stuff in all relevant versions.

Closes: https://bugs.gentoo.org/641654
Bug: https://bugs.gentoo.org/631326
Package-Manager: Portage-2.3.19, Repoman-2.3.6

diff --git a/x11-wm/xpra/Manifest b/x11-wm/xpra/Manifest
index c399106639b3cb0ce49d3dd85828a3ba390bd430..7196d4ad018ec35a1754cd2ab835a89016d4cd35 100644 (file)
--- a/x11-wm/xpra/Manifest
+++ b/x11-wm/xpra/Manifest
@@ -2,3 +2,4 @@ DIST xpra-1.0.6.tar.xz 1892736 BLAKE2B 5eefd99b0900d24717c24da92ed9daf47046080fe
 DIST xpra-1.0.9.tar.xz 1899744 BLAKE2B a8577712c29ff637e69f0faf8224c3318397d104364376415c78099d236746c519ead198fd7436ca6ddccfa0888c394ea0ac81165a5d7d27ded0dbed66f27754 SHA512 99422ac58ebba4e1ba1ce47cf819c119249298ea4f9803d3fb9c4a3939ffd6baf3f34f6f6b3f1645fc17bd00b80410ff11f1fe30c5f79f797acf25b0ce2dd9ec
 DIST xpra-2.0.2.tar.xz 1926876 BLAKE2B 2bd681ebbe6a7041975033c9a30e5b5fdf69352e82d1c56142aac9bb2b620c0ce3242232160cc32b33c74136ae9961c0ab3cb8ae7ec0acf372aebee0583a9318 SHA512 4b36cf9cf96f094011412214368bc452ed597f1927f6488d6856ad80b575d7f37273cf49b8682fdbc137cf581d5a88b17a9241d508278e45e48f9451ba628b68
 DIST xpra-2.1.3.tar.xz 2070192 BLAKE2B b1f54705c877317bf0a3397303af2a516f6e7deb6baa252065f768bd3fd07ec87991b04c14a3aa054da0655543185dfdb99fa2972fb1cd8a2a04d72bb31fafc6 SHA512 aa916953d34477c2c80d99a4d5733586b4122edbc18f2c9952a5d3c9581f7b8e8c55cb1ed4077989876a9a7431faa9c4f7f96f82fc007034f92cacad16429ef8
+DIST xpra-2.2.1.tar.xz 2195508 BLAKE2B 5f94e96ddce7df0001ca3ffbc64570c59f02b1b49fc45c364999f47d188b1ef349018e36ed070cf8c26f60efc77c24741f44856f307b68535c982e6082dc0d7a SHA512 fca213a72805b6b1d533f91cd5e4186bd881e083663488b697c71c79fb4a3bf312fd1491aef78cf363e429c5841d706e444c9e69c72351b1551ea7fc9395c0c6

diff --git a/x11-wm/xpra/xpra-1.0.9.ebuild b/x11-wm/xpra/xpra-1.0.9.ebuild
index 2aa260c03d6b83c1763d4b8fa5201009c00e4ea0..b727b06bcc7779edb36c165400ad7c4278407fd9 100644 (file)
--- a/x11-wm/xpra/xpra-1.0.9.ebuild
+++ b/x11-wm/xpra/xpra-1.0.9.ebuild
@@ -5,7 +5,7 @@ EAPI=6
 
 # PyCObject_Check and PyCObject_AsVoidPtr vanished with python 3.3, and setup.py not python3.2 compat
 PYTHON_COMPAT=( python2_7 )
-inherit distutils-r1 eutils flag-o-matic user tmpfiles
+inherit distutils-r1 eutils flag-o-matic user tmpfiles xdg
 
 DESCRIPTION="X Persistent Remote Apps (xpra) and Partitioning WM (parti) based on wimpiggy"
 HOMEPAGE="http://xpra.org/ http://xpra.org/src/"
@@ -92,6 +92,8 @@ PATCHES=( "${FILESDIR}"/${PN}-0.13.1-ignore-gentoo-no-compile.patch
 pkg_postinst() {
        enewgroup ${PN}
        tmpfiles_process /usr/lib/tmpfiles.d/xpra.conf
+
+       xdg_pkg_postinst
 }
 
 python_prepare_all() {

diff --git a/x11-wm/xpra/xpra-2.1.3.ebuild b/x11-wm/xpra/xpra-2.1.3.ebuild
index 4c0c8a994be7d57b87c65167a4ecd0ed3030e0b4..8416455a5e663602be14ec731e21f7d51e6f7bdf 100644 (file)
--- a/x11-wm/xpra/xpra-2.1.3.ebuild
+++ b/x11-wm/xpra/xpra-2.1.3.ebuild
@@ -5,7 +5,7 @@ EAPI=6
 
 # PyCObject_Check and PyCObject_AsVoidPtr vanished with python 3.3
 PYTHON_COMPAT=( python2_7 )
-inherit distutils-r1 eutils flag-o-matic user tmpfiles
+inherit distutils-r1 eutils flag-o-matic user tmpfiles xdg
 
 DESCRIPTION="X Persistent Remote Apps (xpra) and Partitioning WM (parti) based on wimpiggy"
 HOMEPAGE="http://xpra.org/ http://xpra.org/src/"
@@ -90,6 +90,8 @@ PATCHES=( "${FILESDIR}"/${PN}-0.13.1-ignore-gentoo-no-compile.patch
 pkg_postinst() {
        enewgroup ${PN}
        tmpfiles_process /usr/lib/tmpfiles.d/xpra.conf
+
+       xdg_pkg_postinst
 }
 
 python_prepare_all() {

diff --git a/x11-wm/xpra/xpra-2.2.1.ebuild b/x11-wm/xpra/xpra-2.2.1.ebuild
new file mode 100644 (file)
index 0000000..977f0a2
--- /dev/null
+++ b/x11-wm/xpra/xpra-2.2.1.ebuild
@@ -0,0 +1,146 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+# PyCObject_Check and PyCObject_AsVoidPtr vanished with python 3.3
+PYTHON_COMPAT=( python2_7 )
+inherit distutils-r1 eutils flag-o-matic user tmpfiles xdg
+
+DESCRIPTION="X Persistent Remote Apps (xpra) and Partitioning WM (parti) based on wimpiggy"
+HOMEPAGE="http://xpra.org/ http://xpra.org/src/"
+SRC_URI="http://xpra.org/src/${P}.tar.xz"
+
+LICENSE="GPL-2 BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+client +clipboard csc cups dbus dec_avcodec2 enc_ffmpeg enc_x264 enc_x265 jpeg libav +lz4 lzo opengl pillow pulseaudio server sound test vpx webcam webp"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+       clipboard? ( || ( server client ) )
+       cups? ( dbus )
+       opengl? ( client )
+       || ( client server )
+       client? ( enc_x264? ( dec_avcodec2 ) enc_x265? ( dec_avcodec2 ) )"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+       dev-python/pygobject:2[${PYTHON_USEDEP}]
+       dev-python/pygtk:2[${PYTHON_USEDEP}]
+       x11-libs/gtk+:2
+       x11-libs/libX11
+       x11-libs/libXcomposite
+       x11-libs/libXdamage
+       x11-libs/libXfixes
+       x11-libs/libXrandr
+       x11-libs/libXtst
+       csc? (
+               !libav? ( >=media-video/ffmpeg-1.2.2:0= )
+               libav? ( media-video/libav:0= )
+       )
+       dec_avcodec2? (
+               !libav? ( >=media-video/ffmpeg-2:0= )
+               libav? ( media-video/libav:0= )
+       )
+       enc_ffmpeg? (
+               !libav? ( >=media-video/ffmpeg-3.2.2:0= )
+               libav? ( media-video/libav:0= )
+       )
+       enc_x264? ( media-libs/x264
+               !libav? ( >=media-video/ffmpeg-1.0.4:0= )
+               libav? ( media-video/libav:0= )
+       )
+       enc_x265? ( media-libs/x265
+               !libav? ( >=media-video/ffmpeg-2:0= )
+               libav? ( media-video/libav:0= ) )
+       jpeg? ( media-libs/libjpeg-turbo )
+       opengl? ( dev-python/pygtkglext )
+       pulseaudio? ( media-sound/pulseaudio )
+       sound? ( media-libs/gstreamer:1.0
+               media-libs/gst-plugins-base:1.0
+               dev-python/gst-python:1.0 )
+       vpx? ( media-libs/libvpx virtual/ffmpeg )
+       webp? ( media-libs/libwebp )"
+
+RDEPEND="${COMMON_DEPEND}
+       dev-python/ipython[${PYTHON_USEDEP}]
+       dev-python/netifaces[${PYTHON_USEDEP}]
+       dev-python/rencode[${PYTHON_USEDEP}]
+       virtual/ssh
+       x11-apps/xmodmap
+       cups? ( dev-python/pycups[${PYTHON_USEDEP}] )
+       dbus? ( dev-python/dbus-python[${PYTHON_USEDEP}] )
+       lz4? ( dev-python/lz4[${PYTHON_USEDEP}] )
+       lzo? ( >=dev-python/python-lzo-0.7.0[${PYTHON_USEDEP}] )
+       opengl? (
+               client? ( dev-python/pyopengl_accelerate[${PYTHON_USEDEP}] )
+       )
+       pillow? ( dev-python/pillow[${PYTHON_USEDEP}] )
+       server? ( x11-base/xorg-server[-minimal,xvfb]
+               x11-drivers/xf86-input-void
+       )
+       webcam? ( dev-python/numpy[${PYTHON_USEDEP}]
+               media-libs/opencv[python]
+               dev-python/pyinotify[${PYTHON_USEDEP}] )"
+DEPEND="${COMMON_DEPEND}
+       virtual/pkgconfig
+       >=dev-python/cython-0.16[${PYTHON_USEDEP}]"
+
+PATCHES=( "${FILESDIR}"/${PN}-0.13.1-ignore-gentoo-no-compile.patch
+       "${FILESDIR}"/${PN}-2.0-suid-warning.patch )
+
+pkg_postinst() {
+       enewgroup ${PN}
+       tmpfiles_process /usr/lib/tmpfiles.d/xpra.conf
+
+       xdg_pkg_postinst
+}
+
+python_prepare_all() {
+       sed -e "s:/var/run/xpra:${EROOT}run/xpra:" \
+               -i tmpfiles.d/xpra.conf
+
+       distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+       sed -e "/'pulseaudio'/s:DEFAULT_PULSEAUDIO:$(usex pulseaudio True False):" \
+               -i setup.py || die
+
+       mydistutilsargs=(
+               --without-PIC
+               --without-Xdummy
+               $(use_with client)
+               $(use_with clipboard)
+               $(use_with csc csc_swscale)
+               --without-csc_libyuv
+               $(use_with cups printing)
+               --without-debug
+               $(use_with dbus)
+               $(use_with dec_avcodec2)
+               $(use_with enc_ffmpeg)
+               $(use_with enc_x264)
+               $(use_with enc_x265)
+               --with-gtk2
+               --without-gtk3
+               --without-html5
+               $(use_with jpeg)
+               --without-mdns
+               --without-minify
+               $(use_with opengl)
+               $(use_with server shadow)
+               $(use_with server)
+               $(use_with sound)
+               --with-strict
+               $(use_with vpx)
+               --with-warn
+               $(use_with webcam)
+               $(use_with webp)
+               --with-x11
+       )
+
+       # see https://www.xpra.org/trac/ticket/1080
+       # and http://trac.cython.org/ticket/395
+       append-cflags -fno-strict-aliasing
+
+       export XPRA_SOCKET_DIRS="${EROOT}run/xpra"
+}