media-libs/lensfun: Fix cmake flags, bump to EAPI 6

Thanks-to: Alexander Miller <alex.miller@gmx.de>
Closes: https://bugs.gentoo.org/629578
Package-Manager: Portage-2.3.19, Repoman-2.3.6

diff --git a/media-libs/lensfun/lensfun-0.3.2-r1.ebuild b/media-libs/lensfun/lensfun-0.3.2-r1.ebuild
new file mode 100644 (file)
index 0000000..3085e81
--- /dev/null
+++ b/media-libs/lensfun/lensfun-0.3.2-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit python-single-r1 cmake-utils
+
+DESCRIPTION="Library for rectifying and simulating photographic lens distortions"
+HOMEPAGE="http://lensfun.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-3 CC-BY-SA-3.0" # See README for reasoning.
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~x86-linux"
+IUSE="doc cpu_flags_x86_sse cpu_flags_x86_sse2 test"
+
+RDEPEND="${PYTHON_DEPS}
+       >=dev-libs/glib-2.40
+       media-libs/libpng:0=
+       sys-libs/zlib:="
+DEPEND="${RDEPEND}
+       doc? (
+               app-doc/doxygen
+               dev-python/docutils
+       )"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DOCS=( README.md docs/mounts.txt ChangeLog )
+
+src_configure() {
+       local mycmakeargs=(
+               -DCMAKE_INSTALL_DOCDIR="${EPREFIX}"/usr/share/doc/${PF}/html
+               -DCMAKE_INSTALL_LIBDIR="${EPREFIX}"/usr/$(get_libdir)
+               -DSETUP_PY_INSTALL_PREFIX="${ED}"/usr
+               -DBUILD_LENSTOOL=ON
+               -DBUILD_STATIC=OFF
+               -DBUILD_DOC=$(usex doc)
+               -DBUILD_FOR_SSE=$(usex cpu_flags_x86_sse)
+               -DBUILD_FOR_SSE2=$(usex cpu_flags_x86_sse2)
+               -DBUILD_TESTS=$(usex test)
+       )
+
+       cmake-utils_src_configure
+}