net-libs/tox: bump version to 20160904

diff --git a/net-libs/tox/Manifest b/net-libs/tox/Manifest
index edf391c3dce5774e6aa4347066571690f98baca7..d7e03c08d4cb99e5b51047c907aa560efcb60e13 100644 (file)
--- a/net-libs/tox/Manifest
+++ b/net-libs/tox/Manifest
@@ -1 +1,2 @@
 DIST tox-0_pre20160201.tar.gz 393867 SHA256 4df62a3488429f0b1adbf24312dc39eb140bae88774124072400930967888d19 SHA512 25cd407855bb8a7b916ab36fd84558c08b3d428e9299ad45f362481d2df0cf29f7d74c00f20b5ce5f6f30f1e1db490f3e34b44f55c71b30e23b6d74566587305 WHIRLPOOL 818f2a12eec2a9ac62082a0bd98868bfa48f80453d650475b4be7d64b7d73de1515724f8006a9b0e4a9260be205a9d1dcb556c6fd6052a6d5978d763820db5b2
+DIST tox-0_pre20160904.tar.gz 395495 SHA256 2d4a0d096bdb81b12b10551765fb9f87270e170f10f387f700b3def68cb6c35c SHA512 c0da52ac908141e97e96510a05431cbfb4b9aae81faf4c136c95e21b90a23e3bbe6db88303e48c0f4f3c74ca954229787564b7aa41bfb462afb0d8f8430cdaa1 WHIRLPOOL abd3f61784fac93d983e453515d1e8bc87f7d76651a53ce6f566a277d7ec7c1e03294d95781364ce9ab30f2698c6f5cd552bfa4888f8d5d0d315daf038980c63

diff --git a/net-libs/tox/tox-0_pre20160904.ebuild b/net-libs/tox/tox-0_pre20160904.ebuild
new file mode 100644 (file)
index 0000000..caf7249
--- /dev/null
+++ b/net-libs/tox/tox-0_pre20160904.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools systemd user vcs-snapshot
+
+DESCRIPTION="Encrypted P2P, messaging, and audio/video calling platform"
+HOMEPAGE="https://tox.chat"
+EGIT_COMMIT="755f084e8720b349026c85afbad58954cb7ff1d4"
+SRC_URI="https://github.com/irungentoo/toxcore/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+av daemon log-debug log-error log-info log-trace log-warn +no-log ntox static-libs test"
+
+REQUIRED_USE="^^ ( no-log log-trace log-debug log-info log-warn log-error )"
+
+RDEPEND="
+       av? ( media-libs/libvpx:=
+               media-libs/opus )
+       daemon? ( dev-libs/libconfig )
+       ntox? ( sys-libs/ncurses:0= )
+       >=dev-libs/libsodium-0.6.1:=[asm,urandom]"
+DEPEND="${RDEPEND}
+       test? ( dev-libs/check )
+       virtual/pkgconfig"
+
+src_prepare() {
+       default
+       eautoreconf
+}
+
+src_configure() {
+       econf \
+               $(usex log-trace "--enable-logging --with-log-level=TRACE" "") \
+               $(usex log-debug "--enable-logging --with-log-level=DEBUG" "") \
+               $(usex log-info "--enable-logging --with-log-level=INFO" "") \
+               $(usex log-warn "--enable-logging --with-log-level=WARNING" "") \
+               $(usex log-error "--enable-logging --with-log-level=ERROR" "") \
+               $(use_enable av) \
+               $(use_enable test tests) \
+               $(use_enable ntox) \
+               $(use_enable daemon) \
+               $(use_enable static-libs static)
+}
+
+src_install() {
+       default
+       if use daemon; then
+               newinitd "${FILESDIR}"/initd tox-dht-daemon
+               newconfd "${FILESDIR}"/confd tox-dht-daemon
+               insinto /etc
+               doins "${FILESDIR}"/tox-bootstrapd.conf
+               systemd_dounit "${FILESDIR}"/tox-bootstrapd.service
+       fi
+
+       find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+       if use daemon; then
+               enewgroup ${PN}
+               enewuser ${PN} -1 -1 -1 ${PN}
+               if [[ -f ${EROOT}var/lib/tox-dht-bootstrap/key ]]; then
+                       ewarn "Backwards compatability with the bootstrap daemon might have been"
+                       ewarn "broken a while ago. To resolve this issue, REMOVE the following files:"
+                       ewarn "    ${EROOT}var/lib/tox-dht-bootstrap/key"
+                       ewarn "    ${EROOT}etc/tox-bootstrapd.conf"
+                       ewarn "    ${EROOT}run/tox-dht-bootstrap/tox-dht-bootstrap.pid"
+                       ewarn "Then just re-emerge net-libs/tox"
+               fi
+       fi
+}