media-sound/gnome-music: fix python and introspection deps handling

Convert from python-r1 to python-single-r1 while we don't have any gnome-music module
consumers than gnome-music itself, to not have useless site-packages of these.
Upstream has a hardcoded to python3 shebang, so force it to what python-single-r1
ended up choosing.
Remove ugly upstream 3.4 site-packages path inserts that would potentially defeat our
whole purpose of choosing 3.5 or 3.6 over 3.4 as python provider.

Gentoo-bug: 612380
Thanks-to: Mike Gilbert <floppym@gentoo.org>

diff --git a/media-sound/gnome-music/gnome-music-3.22.2-r1.ebuild b/media-sound/gnome-music/gnome-music-3.22.2-r1.ebuild
new file mode 100644 (file)
index 0000000..e45e036
--- /dev/null
+++ b/media-sound/gnome-music/gnome-music-3.22.2-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{3_4,3_5} )
+
+inherit gnome2 python-single-r1
+
+DESCRIPTION="Music management for Gnome"
+HOMEPAGE="https://wiki.gnome.org/Apps/Music"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+KEYWORDS="~amd64 ~x86"
+
+COMMON_DEPEND="
+       ${PYTHON_DEPS}
+       >=app-misc/tracker-1.9.0[introspection(+)]
+       >=dev-python/pygobject-3.21.1:3[cairo,${PYTHON_USEDEP}]
+       >=dev-libs/glib-2.28:2
+       >=dev-libs/gobject-introspection-1.35.9:=
+       >=media-libs/grilo-0.3.1:0.3[introspection]
+       media-libs/libmediaart:2.0[introspection]
+       >=x11-libs/gtk+-3.19.3:3[introspection]
+"
+# xdg-user-dirs-update needs to be there to create needed dirs
+# https://bugzilla.gnome.org/show_bug.cgi?id=731613
+RDEPEND="${COMMON_DEPEND}
+       || (
+               app-misc/tracker[gstreamer]
+               app-misc/tracker[ffmpeg]
+       )
+       x11-libs/libnotify[introspection]
+       dev-python/dbus-python[${PYTHON_USEDEP}]
+       dev-python/requests[${PYTHON_USEDEP}]
+       media-libs/gstreamer:1.0[introspection]
+       media-libs/gst-plugins-base:1.0[introspection]
+       media-plugins/gst-plugins-meta:1.0
+       media-plugins/grilo-plugins:0.3[tracker]
+       x11-misc/xdg-user-dirs
+"
+DEPEND="${COMMON_DEPEND}
+       app-text/yelp-tools
+       >=dev-util/intltool-0.26
+       virtual/pkgconfig
+"
+
+pkg_setup() {
+       python_setup
+}
+
+src_prepare() {
+       sed -e '/sys.path.insert/d' -i ${S}/gnome-music.in || die "python fixup sed failed"
+       gnome2_src_prepare
+}
+
+src_install() {
+       gnome2_src_install
+       python_fix_shebang ${D}usr/bin/gnome-music
+}

diff --git a/profiles/base/package.use b/profiles/base/package.use
index 46efc42d976659f6d2179484771932d2744cebf5..cf8735ba350690e47572969d11e707ac17c0f7cc 100644 (file)
--- a/profiles/base/package.use
+++ b/profiles/base/package.use
@@ -1,6 +1,10 @@
 # Copyright 1999-2017 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
+# Mart Raudsepp <leio@gentoo.org> (23 Mar 2017)
+# Only python3 supported
+media-sound/gnome-music python_single_target_python3_4
+
 # Andreas Sturmlechner <asturm@gentoo.org> (23 Mar 2017)
 # Only >=python3_5 supported
 dev-util/kdevelop-python:5 python_single_target_python3_5