net-analyzer/bmon: Add live ebuild

Package-Manager: Portage-2.3.64, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

diff --git a/net-analyzer/bmon/bmon-999.ebuild b/net-analyzer/bmon/bmon-999.ebuild
new file mode 100644 (file)
index 0000000..cabc2a7
--- /dev/null
+++ b/net-analyzer/bmon/bmon-999.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools git-r3 linux-info toolchain-funcs
+
+DESCRIPTION="interface bandwidth monitor"
+HOMEPAGE="http://www.infradead.org/~tgr/bmon/ https://github.com/tgraf/bmon/"
+EGIT_REPO_URI="https://github.com/tgraf/bmon/"
+
+LICENSE="BSD-2 MIT"
+SLOT="0"
+KEYWORDS=""
+
+RDEPEND="
+       >=sys-libs/ncurses-5.3-r2:0=
+       dev-libs/confuse:=
+       dev-libs/libnl:3
+"
+DEPEND="
+       ${RDEPEND}
+       virtual/pkgconfig
+"
+
+DOCS=( ChangeLog )
+
+CONFIG_CHECK="~NET_SCHED"
+ERROR_NET_SCHED="
+       CONFIG_NET_SCHED is not set when it should be.
+       Run ${PN} -i proc to use the deprecated proc interface instead.
+"
+PATCHES=(
+       "${FILESDIR}"/${PN}-3.6-docdir-examples.patch
+)
+
+src_prepare() {
+       default
+       eautoreconf
+}
+
+src_configure() {
+       econf \
+               CURSES_LIB="$( $(tc-getPKG_CONFIG) --libs ncurses)" \
+               --docdir="/usr/share/doc/${PF}"
+}