app-text/libstaroffice: New package

Required by >=app-office/libreoffice-5.3

Gentoo-bug: 592354

Package-Manager: portage-2.3.0

diff --git a/app-text/libstaroffice/libstaroffice-9999.ebuild b/app-text/libstaroffice/libstaroffice-9999.ebuild
new file mode 100644 (file)
index 0000000..e5d61b8
--- /dev/null
+++ b/app-text/libstaroffice/libstaroffice-9999.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+EGIT_REPO_URI="https://github.com/fosnola/libstaroffice.git"
+
+[[ ${PV} == 9999 ]] && GITECLASS="git-r3 autotools"
+inherit eutils ${GITECLASS}
+unset GITECLASS
+
+DESCRIPTION="Import filter for old StarOffice documents"
+HOMEPAGE="https://github.com/fosnola/libstaroffice"
+[[ ${PV} == 9999 ]] || SRC_URI="http://dev-www.libreoffice.org/src/${P}.tar.bz2"
+
+LICENSE="|| ( LGPL-2.1+ MPL-2.0 )"
+SLOT="0"
+[[ ${PV} == 9999 ]] || \
+KEYWORDS="~amd64 ~x86"
+
+IUSE="debug doc tools +zlib"
+
+RDEPEND="
+       dev-libs/librevenge
+       zlib? ( sys-libs/zlib )
+"
+DEPEND="${RDEPEND}
+       doc? ( app-doc/doxygen )
+"
+
+src_prepare() {
+       default
+       [[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+       econf \
+               $(use_enable debug) \
+               $(use_with doc docs) \
+               $(use_enable tools) \
+               $(use_enable zlib zip)
+}
+
+src_install() {
+       default
+       prune_libtool_files --all
+}

diff --git a/app-text/libstaroffice/metadata.xml b/app-text/libstaroffice/metadata.xml
new file mode 100644 (file)
index 0000000..27a1e93
--- /dev/null
+++ b/app-text/libstaroffice/metadata.xml
@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+       <maintainer type="project">
+               <email>office@gentoo.org</email>
+               <name>Gentoo Office project</name>
+       </maintainer>
+       <use>
+               <flag name="tools">Build conversion tools</flag>
+               <flag name="zlib">Enable support for compressed data</flag>
+       </use>
+       <upstream>
+               <remote-id type="github">fosnola/libstaroffice</remote-id>
+       </upstream>
+</pkgmetadata>