net-libs/tox: update to tox 0.2.9

This commit updates the version from tox-0.2.8 to tox-0.2.9.

Signed-off-by: Josiah Mullins <JoMull01@protonmail.com>
Package-Manager: Portage-2.3.51, Repoman-2.3.11
Closes: https://github.com/gentoo/gentoo/pull/11072
Signed-off-by: Michał Górny <mgorny@gentoo.org>

diff --git a/net-libs/tox/Manifest b/net-libs/tox/Manifest
index 9a173c626105ecccc4533add29e30e4f6f2c65b3..d9048b8112202a37fe6e9b8df8dd36f8b0cd9d85 100644 (file)
--- a/net-libs/tox/Manifest
+++ b/net-libs/tox/Manifest
@@ -1 +1,2 @@
 DIST c-toxcore-0.2.8.tar.gz 502907 BLAKE2B 0ca2c861b3cd982b471fac5cf8bdacd21c3248118846cc17e51f33ba04cf3da12a64578744e47daa27bb8613762a6f562eb550f0b7af05a66696412f6d0a6360 SHA512 a23a87a74fe97091b00ea76676a22578ed1e2426ac777146bb6efc984f1bfd3fff0d7fb149691155b8e2db56e1e088a1884536e5b717ff5c45a87b437f275735
+DIST c-toxcore-0.2.9.tar.gz 510806 BLAKE2B e67bdb86757d1431cc9d627dbc9afa9f54c3deb7814b38c2126849d10e9225aa58d2b23d175622678be74894ea197d3084719422a605d95eb4c55c4597a79f98 SHA512 917826a906a9ca4f04f34494616b8e36ec9e74c6b0709c50e8fe2dd9da680d170013fef242a3fe1b834e8e54cd2dde6be1c14e5d977f8531436ef34280bc3966

diff --git a/net-libs/tox/tox-0.2.9.ebuild b/net-libs/tox/tox-0.2.9.ebuild
new file mode 100644 (file)
index 0000000..046b33f
--- /dev/null
+++ b/net-libs/tox/tox-0.2.9.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2019 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils systemd user
+
+MY_P="c-toxcore-${PV}"
+DESCRIPTION="Encrypted P2P, messaging, and audio/video calling platform"
+HOMEPAGE="https://tox.chat"
+SRC_URI="https://github.com/TokTok/c-toxcore/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0/0.2"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="+av daemon ipv6 log-debug +log-error log-info log-trace log-warn static-libs test"
+
+REQUIRED_USE="?? ( log-debug log-error log-info log-trace log-warn )"
+
+RDEPEND="
+       av? ( media-libs/libvpx:=
+               media-libs/opus )
+       daemon? ( dev-libs/libconfig )
+       >=dev-libs/libsodium-0.6.1:=[asm,urandom,-minimal]"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+       cmake-utils_src_prepare
+       #remove faulty tests
+       for testname in bootstrap lan_discovery save_compatibility tcp_relay tox_many_tcp; do
+               sed -i -e "/^auto_test(${testname})$/d" CMakeLists.txt || die
+       done
+}
+
+src_configure() {
+       local mycmakeargs=(
+               -DAUTOTEST=$(usex test)
+               -DBOOTSTRAP_DAEMON=$(usex daemon)
+               -DBUILD_MISC_TESTS=$(usex test)
+               -DBUILD_TOXAV=$(usex av)
+               -DENABLE_SHARED=ON
+               -DENABLE_STATIC=$(usex static-libs)
+               -DMUST_BUILD_TOXAV=$(usex av))
+       if use test; then
+               mycmakeargs+=(
+                       -DBUILD_AV_TEST=$(usex av)
+                       -DTEST_TIMEOUT_SECONDS=120
+                       -DUSE_IPV6=$(usex ipv6))
+       else
+               mycmakeargs+=(
+                       -DBUILD_AV_TEST=OFF
+                       -DUSE_IPV6=OFF)
+       fi
+
+       if use log-trace; then
+               mycmakeargs+=(-DMIN_LOGGER_LEVEL="TRACE")
+       elif use log-debug; then
+               mycmakeargs+=(-DMIN_LOGGER_LEVEL="DEBUG")
+       elif use log-info; then
+               mycmakeargs+=(-DMIN_LOGGER_LEVEL="INFO")
+       elif use log-warn; then
+               mycmakeargs+=(-DMIN_LOGGER_LEVEL="WARNING")
+       elif use log-error; then
+               mycmakeargs+=(-DMIN_LOGGER_LEVEL="ERROR")
+       else
+               mycmakeargs+=(-DMIN_LOGGER_LEVEL="")
+               einfo "Logging disabled"
+       fi
+
+       cmake-utils_src_configure
+}
+
+src_install() {
+       cmake-utils_src_install
+
+       if use daemon; then
+               newinitd "${FILESDIR}"/initd tox-dht-daemon
+               newconfd "${FILESDIR}"/confd tox-dht-daemon
+               insinto /etc
+               doins "${FILESDIR}"/tox-bootstrapd.conf
+               systemd_dounit "${FILESDIR}"/tox-bootstrapd.service
+       fi
+}
+
+pkg_postinst() {
+       if use daemon; then
+               enewgroup tox
+               enewuser tox -1 -1 -1 tox
+               if [[ -f ${EROOT}/var/lib/tox-dht-bootstrap/key ]]; then
+                       ewarn "Backwards compatability with the bootstrap daemon might have been"
+                       ewarn "broken a while ago. To resolve this issue, REMOVE the following files:"
+                       ewarn "    ${EROOT}/var/lib/tox-dht-bootstrap/key"
+                       ewarn "    ${EROOT}/etc/tox-bootstrapd.conf"
+                       ewarn "    ${EROOT}/run/tox-dht-bootstrap/tox-dht-bootstrap.pid"
+                       ewarn "Then just re-emerge net-libs/tox"
+               fi
+       fi
+}