net-firewall/ebtables: drop /etc/ethertypes

Bug: https://bugs.gentoo.org/647458
Package-Manager: Portage-2.3.24_p18, Repoman-2.3.6_p99

diff --git a/net-firewall/ebtables/ebtables-2.0.10.4-r1.ebuild b/net-firewall/ebtables/ebtables-2.0.10.4-r1.ebuild
index 83e49e5a63cd529c91c1b91ef073b116431e3ea0..c506fa3d0bfc3196511d879c09f53545919a98c2 100644 (file)
--- a/net-firewall/ebtables/ebtables-2.0.10.4-r1.ebuild
+++ b/net-firewall/ebtables/ebtables-2.0.10.4-r1.ebuild
@@ -18,7 +18,10 @@ KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86"
 IUSE="+perl static"
 
 # The ebtables-save script is written in perl.
-RDEPEND="perl? ( dev-lang/perl )"
+RDEPEND="perl? ( dev-lang/perl )
+       !<net-firewall/iptables-1.6.2-r2[nftables(-)]
+       !net-misc/ethertypes
+"
 
 S=${WORKDIR}/${MY_P}
 

diff --git a/net-firewall/ebtables/ebtables-2.0.10.4-r2.ebuild b/net-firewall/ebtables/ebtables-2.0.10.4-r2.ebuild
new file mode 100644 (file)
index 0000000..4fe72ef
--- /dev/null
+++ b/net-firewall/ebtables/ebtables-2.0.10.4-r2.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit versionator toolchain-funcs flag-o-matic
+
+MY_PV=$(replace_version_separator 3 '-' )
+MY_P=${PN}-v${MY_PV}
+
+DESCRIPTION="Controls Ethernet frame filtering on a Linux bridge, MAC NAT and brouting"
+HOMEPAGE="http://ebtables.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86"
+IUSE="+perl static"
+
+# The ebtables-save script is written in perl.
+RDEPEND="perl? ( dev-lang/perl )
+       net-misc/ethertypes"
+
+S=${WORKDIR}/${MY_P}
+
+pkg_setup() {
+       if use static; then
+               ewarn "You've chosen static build which is useful for embedded devices."
+               ewarn "It has no init script. Make sure that's really what you want."
+       fi
+}
+
+src_prepare() {
+       # Enhance ebtables-save to take table names as parameters bug #189315
+       local PATCHES=( "${FILESDIR}/${PN}-2.0.8.1-ebt-save.diff" )
+
+       default
+
+       sed -i -e "s,^MANDIR:=.*,MANDIR:=/usr/share/man," \
+               -e "s,^BINDIR:=.*,BINDIR:=/sbin," \
+               -e "s,^INITDIR:=.*,INITDIR:=/usr/share/doc/${PF}," \
+               -e "s,^SYSCONFIGDIR:=.*,SYSCONFIGDIR:=/usr/share/doc/${PF}," \
+               -e "s,^LIBDIR:=.*,LIBDIR:=/$(get_libdir)/\$(PROGNAME)," Makefile
+}
+
+src_compile() {
+       # This package uses _init functions to initialise extensions. With
+       # --as-needed this will not work.
+       append-ldflags $(no-as-needed)
+       emake \
+               CC="$(tc-getCC)" \
+               CFLAGS="${CFLAGS}" \
+               $(use static && echo static)
+}
+
+src_install() {
+       if ! use static; then
+               emake DESTDIR="${D}" install
+               keepdir /var/lib/ebtables/
+               newinitd "${FILESDIR}"/ebtables.initd-r1 ebtables
+               newconfd "${FILESDIR}"/ebtables.confd-r1 ebtables
+               if ! use perl; then
+                       rm "${ED}"/sbin/ebtables-save || die
+               fi
+               # Bug 647458
+               rm "${ED%/}"/etc/ethertypes || die
+       else
+               into /
+               newsbin static ebtables
+       fi
+       dodoc ChangeLog THANKS
+}

diff --git a/net-firewall/ebtables/ebtables-2.0.10.4.ebuild b/net-firewall/ebtables/ebtables-2.0.10.4.ebuild
index d4f1785a01fabf29670d7286aa91559a85d665c1..10bbd3d6985ec7586c085ff1a09ab1508154e3b0 100644 (file)
--- a/net-firewall/ebtables/ebtables-2.0.10.4.ebuild
+++ b/net-firewall/ebtables/ebtables-2.0.10.4.ebuild
@@ -17,6 +17,11 @@ IUSE="static"
 LICENSE="GPL-2"
 SLOT="0"
 
+RDEPEND="
+       !<net-firewall/iptables-1.6.2-r2[nftables(-)]
+       !net-misc/ethertypes
+"
+
 S=${WORKDIR}/${MY_P}
 
 pkg_setup() {