dev-libs/libevent: Version 2.1.9_beta

Package-Manager: Portage-2.3.60, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

diff --git a/dev-libs/libevent/Manifest b/dev-libs/libevent/Manifest
index ba25e280bed310b310d61f8c3f2cc24e7a5ee03b..9171930e0d245d8fa0fd3f08d556cf7643c28369 100644 (file)
--- a/dev-libs/libevent/Manifest
+++ b/dev-libs/libevent/Manifest
@@ -1 +1,2 @@
 DIST libevent-2.1.8.tar.gz 1026485 BLAKE2B f1ceb740aa776a7c26f52916d771af7f4bb351cadf858ef991ab015e5897e34579c6af1f4ed3b516d5be2ac7cb3a7c27ac9d3020dbb04ac7670118616a264561 SHA512 a2fd3dd111e73634e4aeb1b29d06e420b15c024d7b47778883b5f8a4ff320b5057a8164c6d50b53bd196c79d572ce2639fe6265e03a93304b09c22b41e4c2a17
+DIST libevent-2.1.9_beta.tar.gz 1067050 BLAKE2B d59f424995742e6a57df74420d91c8a1614d7dbb6e3928a3dd666269f7c2f4876d6fedd649e4e947a6db63c15f69c18866bda9997c3bb3571452a8dbf126916a SHA512 672bff332292ec76503bc0ccb9462058e093f1867740fece51f77bb666c77c85e10271730b32b36d6faa9ab2ccee0433879457e201bf94b6bf704dba2c066051

diff --git a/dev-libs/libevent/libevent-2.1.9_beta.ebuild b/dev-libs/libevent/libevent-2.1.9_beta.ebuild
new file mode 100644 (file)
index 0000000..9c98cb2
--- /dev/null
+++ b/dev-libs/libevent/libevent-2.1.9_beta.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools multilib-minimal
+
+DESCRIPTION="Library to execute a function when a specific event occurs on a file descriptor"
+HOMEPAGE="http://libevent.org/ https://github.com/libevent/libevent/"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/release-${PV/_/-}/${P/_/-}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+# libevent-2.1.so.6
+SLOT="0/2.1-6"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="debug libressl +ssl static-libs test +threads"
+
+DEPEND="
+       ssl? (
+               !libressl? ( >=dev-libs/openssl-1.0.1h-r2:0=[${MULTILIB_USEDEP}] )
+               libressl? ( dev-libs/libressl:0=[${MULTILIB_USEDEP}] )
+       )
+"
+RDEPEND="
+       ${DEPEND}
+       !<=dev-libs/9libs-1.0
+"
+MULTILIB_WRAPPED_HEADERS=(
+       /usr/include/event2/event-config.h
+)
+S=${WORKDIR}/${P/_/-}
+
+src_prepare() {
+       default
+       eautoreconf
+}
+
+multilib_src_configure() {
+       # fix out-of-source builds
+       mkdir -p test || die
+
+       ECONF_SOURCE="${S}" \
+       econf \
+               --disable-samples \
+               $(use_enable debug debug-mode) \
+               $(use_enable debug malloc-replacement) \
+               $(use_enable ssl openssl) \
+               $(use_enable static-libs static) \
+               $(use_enable test libevent-regress) \
+               $(use_enable threads thread-support)
+}
+
+src_test() {
+       # The test suite doesn't quite work (see bug #406801 for the latest
+       # installment in a riveting series of reports).
+       :
+       # emake -C test check | tee "${T}"/tests
+}
+
+DOCS=( ChangeLog{,-1.4,-2.0} )
+
+multilib_src_install_all() {
+       einstalldocs
+       find "${ED}" -name '*.la' -delete || die
+}

diff --git a/dev-libs/libevent/libevent-9999.ebuild b/dev-libs/libevent/libevent-9999.ebuild
index 278ad77c4d5ad0334fdc7ebf926194f2fb58b850..16a0b3af8b698fc4529a8b3253026e4a6f938195 100644 (file)
--- a/dev-libs/libevent/libevent-9999.ebuild
+++ b/dev-libs/libevent/libevent-9999.ebuild
@@ -1,8 +1,8 @@
 # Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
-inherit autotools eutils git-r3 multilib-minimal
+EAPI=7
+inherit autotools git-r3 multilib-minimal
 
 DESCRIPTION="Library to execute a function when a specific event occurs on a file descriptor"
 EGIT_REPO_URI="https://github.com/libevent/libevent"
@@ -57,5 +57,5 @@ multilib_src_configure() {
 
 multilib_src_install_all() {
        einstalldocs
-       prune_libtool_files
+       find "${ED}" -name '*.la' -delete || die
 }