dev-libs/amdgpu-pro-opencl: bump to 18.20.684755, enable multilib

Multilib support kindly provided by Georgy Yakovlev
<gyakovlev@gentoo.org>.

Closes: https://github.com/gentoo/gentoo/pull/9113
Signed-off-by: Marek Szuba <marecki@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

diff --git a/dev-libs/amdgpu-pro-opencl/Manifest b/dev-libs/amdgpu-pro-opencl/Manifest
index 05d329a35582b447854c3f45a93a20ba0eafa7df..83337405581d320c4c04ce0fffb5f1cf301cdd5a 100644 (file)
--- a/dev-libs/amdgpu-pro-opencl/Manifest
+++ b/dev-libs/amdgpu-pro-opencl/Manifest
@@ -1,2 +1,3 @@
 DIST amdgpu-pro-17.50-552542.tar.xz 549501204 BLAKE2B 37dcda126a3bda4e87b64ce260c7e4b65a1b864363c51f06e3152f152b83a60074331e6a0bf7b831c059a50192dea8add9b38ed16971c87293ce0e56ddf26bb2 SHA512 060e96609cf1a013fddf10db9bba4b512750e5188671a669e2582c28a03213b40d073031e35a617b982374d9d1cd4078f43b27053ee34be7c83873c0814ed196
 DIST amdgpu-pro-18.20-606296.tar.xz 230733856 BLAKE2B 21a498a894a9712d9f0277fae7f704413be0cd01cebbe427008fa3d181d03b58268e74bd3cdaf0dfb9aeca2871dad82b4aa640bbce690ca461e3f3e4acf01ffd SHA512 6575bf963e5714657914d9116de4d9b1835851fe0609b1f072b1fbdf73c068da77aba0eca1c9cce6e05e6cd8f2c1ed6b4bd6ab4ef334be5ff796ee6a3ad73831
+DIST amdgpu-pro-18.20-684755-ubuntu-16.04.tar.xz 229474380 BLAKE2B f589aad71f093b74e37de40ac7c45ebbbeff93609b2fff1baaba711347a4641ef17acdcbe69d371372510a48bd48262cf6269c1f4d05e264023d52a425a423f2 SHA512 240e701acfde4ebe665cf69c8bd3710d036f450822aeb7ee2a21caab289af44167afda1d3b8d0dbe2c46c4e63d9b6fb5e96778311f342c26f334dc7beb4a2d5b

diff --git a/dev-libs/amdgpu-pro-opencl/amdgpu-pro-opencl-18.20.684755.ebuild b/dev-libs/amdgpu-pro-opencl/amdgpu-pro-opencl-18.20.684755.ebuild
new file mode 100644 (file)
index 0000000..739777f
--- /dev/null
+++ b/dev-libs/amdgpu-pro-opencl/amdgpu-pro-opencl-18.20.684755.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MULTILIB_COMPAT=( abi_x86_{32,64} )
+
+inherit unpacker multilib-minimal
+
+SUPER_PN='amdgpu-pro'
+MY_PV=$(ver_rs 2 '-')
+
+DESCRIPTION="Proprietary OpenCL implementation for AMD GPUs"
+HOMEPAGE="https://support.amd.com/en-us/kb-articles/Pages/Radeon-Software-for-Linux-Release-Notes.aspx"
+SRC_URI="${SUPER_PN}-${MY_PV}-ubuntu-16.04.tar.xz"
+
+LICENSE="AMD-GPU-PRO-EULA"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RESTRICT="mirror fetch strip"
+
+COMMON="app-eselect/eselect-opencl
+       dev-libs/ocl-icd"
+DEPEND="${COMMON}"
+RDEPEND="${COMMON}"
+
+QA_PREBUILT="/opt/amdgpu/lib*/*"
+
+S="${WORKDIR}/${SUPER_PN}-${MY_PV}-ubuntu-16.04"
+
+pkg_nofetch() {
+       local pkgver=$(ver_cut 1-2)
+       einfo "Please download the Radeon Software for Linux Driver ${pkgver} for Ubuntu 16 from"
+       einfo "    ${HOMEPAGE}"
+       einfo "The archive should then be placed into your distfiles directory."
+}
+
+src_unpack() {
+       default
+       multilib_parallel_foreach_abi multilib_src_unpack
+}
+
+multilib_src_unpack() {
+       local deb_abi
+       [[ ${ABI} == x86 ]] && deb_abi=i386
+       mkdir -p "${BUILD_DIR}" || die
+       pushd "${BUILD_DIR}" >/dev/null || die
+       unpack_deb "${S}/opencl-orca-amdgpu-pro-icd_${MY_PV}_${deb_abi:-${ABI}}.deb"
+       popd >/dev/null || die
+}
+
+multilib_src_install() {
+       local dir_abi short_abi
+       [[ ${ABI} == x86 ]] && dir_abi=i386-linux-gnu && short_abi=32
+       [[ ${ABI} == amd64 ]] && dir_abi=x86_64-linux-gnu && short_abi=64
+
+       into "/opt/amdgpu"
+       dolib.so "opt/${SUPER_PN}/lib/${dir_abi}"/*
+
+       insinto /etc/OpenCL/vendors
+       echo "/opt/amdgpu/$(get_libdir)/libamdocl-orca${short_abi}.so" \
+               > "${T}/${SUPER_PN}-${ABI}.icd" || die "Failed to generate ICD file for ABI ${ABI}"
+       doins "${T}/${SUPER_PN}-${ABI}.icd"
+}
+
+pkg_postinst() {
+       if [[ -z "${REPLACING_VERSIONS}" ]]; then
+               ewarn "Please note that using proprietary OpenCL libraries together with the"
+               ewarn "Open Source amdgpu stack is not officially supported by AMD. Do not ask them"
+               ewarn "for support in case of problems with this package."
+               ewarn ""
+               ewarn "Furthermore, if you have the whole AMDGPU-Pro stack installed this package"
+               ewarn "will almost certainly conflict with it. This might change once AMDGPU-Pro"
+               ewarn "has become officially supported by Gentoo."
+       fi
+
+       "${ROOT}"/usr/bin/eselect opencl set --use-old ocl-icd
+}