net-libs/libnice: bump to 0.1.15

Closes: https://bugs.gentoo.org/673280
Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

diff --git a/net-libs/libnice/Manifest b/net-libs/libnice/Manifest
index f3c17afb32c03b975735df28a09111ca68bfd0c5..35bfe6c5ad0aa069b7f30e44d1d3ca053fa4a01a 100644 (file)
--- a/net-libs/libnice/Manifest
+++ b/net-libs/libnice/Manifest
@@ -1 +1,2 @@
 DIST libnice-0.1.13.tar.gz 912374 BLAKE2B ae8ac3af7b5f355e3c7b961bfa60759ba71c8cc6ddb6cb5faaf1c6fe347785f36340a9f8977a1689595c265349a1b34305f41288cf951fa938b0411cec3acc0d SHA512 c9bb81e8cd0b4e3673dba07ce08a16dd8821831339b44f1006510cdc09f9ae4c6eb7d43230711a2509867acb8d7df71821c411830dbf71c5a5d7e802f14a32c1
+DIST libnice-0.1.15.tar.gz 1064100 BLAKE2B 81f06ba599b01084586a8d904b9ae513d6bc3531ec42674648fda320eea6cd9348acf423571922bab4e338bf135f85b292046352ed6f5e4fefba736d787b1ff1 SHA512 60a8bcca06c0ab300dfabbf13e45aeac2085d553c420c5cc4d2fdeb46b449b2b9c9aee8015b0662c16bd1cecf5a49824b7e24951a8a0b66a87074cb00a619c0c

diff --git a/net-libs/libnice/libnice-0.1.15.ebuild b/net-libs/libnice/libnice-0.1.15.ebuild
new file mode 100644 (file)
index 0000000..990b285
--- /dev/null
+++ b/net-libs/libnice/libnice-0.1.15.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit multilib-minimal xdg
+
+DESCRIPTION="An implementation of the Interactice Connectivity Establishment standard (ICE)"
+HOMEPAGE="https://nice.freedesktop.org/wiki/"
+SRC_URI="https://nice.freedesktop.org/releases/${P}.tar.gz"
+
+LICENSE="|| ( MPL-1.1 LGPL-2.1 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="+gnutls +introspection libressl +upnp"
+
+RDEPEND="
+       >=dev-libs/glib-2.48:2[${MULTILIB_USEDEP}]
+       introspection? ( >=dev-libs/gobject-introspection-1.30.0:= )
+       gnutls? ( >=net-libs/gnutls-2.12.0:0=[${MULTILIB_USEDEP}] )
+       !gnutls? (
+               libressl? ( dev-libs/libressl:0=[${MULTILIB_USEDEP}] )
+               !libressl? ( dev-libs/openssl:0=[${MULTILIB_USEDEP}] ) )
+       upnp? ( >=net-libs/gupnp-igd-0.2.4:=[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+       dev-util/glib-utils
+       >=dev-util/gtk-doc-am-1.10
+       >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+"
+
+multilib_src_configure() {
+       # gstreamer plugin split off into media-plugins/gst-plugins-libnice
+       ECONF_SOURCE=${S} \
+       econf \
+               --enable-compile-warnings=yes \
+               --disable-static \
+               --disable-static-plugins \
+               --without-gstreamer \
+               --without-gstreamer-0.10 \
+               --with-crypto-library=$(usex gnutls gnutls openssl) \
+               $(multilib_native_use_enable introspection) \
+               $(use_enable upnp gupnp)
+
+       if multilib_is_native_abi; then
+               ln -s {"${S}"/,}docs/reference/libnice/html || die
+       fi
+}
+
+multilib_src_install_all() {
+       einstalldocs
+       find "${ED}" -name '*.la' -delete || die
+}
+
+multilib_src_test() {
+       emake -j1 check
+}