media-sound/tunapie: python-single-r1, EAPI=6

diff --git a/media-sound/tunapie/tunapie-2.1.17-r1.ebuild b/media-sound/tunapie/tunapie-2.1.17-r1.ebuild
new file mode 100644 (file)
index 0000000..88ce802
--- /dev/null
+++ b/media-sound/tunapie/tunapie-2.1.17-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+inherit eutils python-single-r1
+
+DESCRIPTION="Directory browser for Radio and TV streams"
+HOMEPAGE="http://tunapie.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="offensive"
+
+RDEPEND=">=dev-python/wxpython-2.6[${PYTHON_USEDEP}]
+       ${PYTHON_DEPS}"
+DEPEND="${RDEPEND}"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+src_prepare() {
+       default
+
+       # fix pixmap lookup
+       sed -i -e 's@../pixmaps@../../share/pixmaps@' \
+               src/tunapie2_main.py || die
+
+       # the original script requires more sed than code,
+       cat > tunapie <<-_EOF_ || die
+               #!/bin/sh
+               exec ${EPYTHON} /usr/lib/tunapie/Tunapie.py
+       _EOF_
+}
+
+src_install() {
+       dobin tunapie
+       doman tunapie.1
+       dodoc CHANGELOG README
+
+       python_moduleinto /usr/lib/tunapie
+       python_domodule src/{*.py,*.png}
+
+       doicon src/tplogo.xpm
+       domenu tunapie.desktop
+
+       dodir /etc
+       usex offensive 1 0 > "${ED%/}"/etc/tunapie.config || die
+}

diff --git a/media-sound/tunapie/tunapie-2.1.17.ebuild b/media-sound/tunapie/tunapie-2.1.17.ebuild
deleted file mode 100644 (file)
index 7c81522..0000000
--- a/media-sound/tunapie/tunapie-2.1.17.ebuild
+++ /dev/null
@@ -1,57 +0,0 @@
-# Copyright 1999-2011 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI=3
-PYTHON_DEPEND="2"
-inherit eutils multilib python
-
-DESCRIPTION="Directory browser for Radio and TV streams"
-HOMEPAGE="http://tunapie.sourceforge.net"
-SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="offensive"
-
-RDEPEND=">=dev-python/wxpython-2.6"
-DEPEND=""
-
-pkg_setup() {
-       python_set_active_version 2
-       python_pkg_setup
-}
-
-src_prepare() {
-       sed -i -e "s:/usr/local/share:/usr/$(get_libdir):" ${PN} \
-               || die "sed failed"
-}
-
-src_install() {
-       dobin ${PN} || die "dobin failed"
-       doman ${PN}.1
-       dodoc CHANGELOG README
-
-       doicon src/tplogo.xpm
-       domenu ${PN}.desktop
-
-       insinto /usr/$(get_libdir)/${PN}
-       doins src/{*.py,*.png} || die "doins failed"
-
-       dodir /etc
-
-       if use offensive; then
-               echo 1 > "${D}"/etc/${PN}.config
-       else
-               echo 0 > "${D}"/etc/${PN}.config
-       fi
-}
-
-pkg_postinst() {
-       python_mod_optimize /usr/$(get_libdir)/${PN}
-}
-
-pkg_postrm() {
-       python_mod_cleanup /usr/$(get_libdir)/${PN}
-}