net-libs/gnome-online-accounts: bump to 3.28.1

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

diff --git a/net-libs/gnome-online-accounts/Manifest b/net-libs/gnome-online-accounts/Manifest
index 0d5e1b2ca4b1ca06216b95467fd1284a31581d1a..1b3bd5ba27b68d6fd74fe1ca7fdc4126bebda461 100644 (file)
--- a/net-libs/gnome-online-accounts/Manifest
+++ b/net-libs/gnome-online-accounts/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-online-accounts-3.24.5.tar.xz 1391332 BLAKE2B 9085cbb0c92bfcd338d5feca7ebdd3e3b15483e47fe29faffb8f9fb474663adeaf8d5cc81673c552652c9444e742f2782fd727c93bf488f5c976bde72d00ddce SHA512 8db35d21f0639e7452ec5cb34455b6d48a77fe0755c525f22e5235abe758f09ad5a4685e5e4912a53def298c76a13b558704a83803b5aabecc13a0f9bc3ae0e4
 DIST gnome-online-accounts-3.28.0.tar.xz 1531200 BLAKE2B 104429ab97647c2b006c4f95f803d8be8f2d2a91b06f2b145b126b1ab34253c8870ed9f8a3b5be307cae3fc55a4894cb1e9479c680d1c14a558d525d962bcf01 SHA512 b5f83544aca0cd24dbc778a492e0da4ca82eb6acaab375daaf7aa1482acfd31c1ba82c1afc127a8890a63e883ac8a1f277da906819573d672d2d3da7f582c02b
+DIST gnome-online-accounts-3.28.1.tar.xz 1539480 BLAKE2B f4d842025c9c55de70f4d613c6193cdbd387e20f167c61cc52b36c0080da6b9e9a45fc4f8452cfd0a573395ddfd513b984910f3c5d802ef2979041db7a2a8203 SHA512 66cfc8a0e193bf4eaf49fecb15e166b2c565c3c164b8de1d191fc7c966d6cfdb19d662dd0bd0b6b80e3b6a7680796aa6d54700b9002b4cae4fe919bb681a8f06

diff --git a/net-libs/gnome-online-accounts/gnome-online-accounts-3.28.1.ebuild b/net-libs/gnome-online-accounts/gnome-online-accounts-3.28.1.ebuild
new file mode 100644 (file)
index 0000000..7631b70
--- /dev/null
+++ b/net-libs/gnome-online-accounts/gnome-online-accounts-3.28.1.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala
+
+DESCRIPTION="GNOME framework for accessing online accounts"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeOnlineAccounts"
+
+LICENSE="LGPL-2+"
+SLOT="0/1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="debug gnome +introspection kerberos vala" # telepathy"
+REQUIRED_USE="vala? ( introspection )"
+
+# pango used in goaeditablelabel
+# libsoup used in goaoauthprovider
+# goa kerberos provider is incompatible with app-crypt/heimdal, see
+# https://bugzilla.gnome.org/show_bug.cgi?id=692250
+# json-glib-0.16 needed for bug #485092
+RDEPEND="
+       >=dev-libs/glib-2.52:2
+       >=app-crypt/libsecret-0.5
+       >=dev-libs/json-glib-0.16
+       dev-libs/libxml2:2
+       >=net-libs/libsoup-2.42:2.4
+       net-libs/rest:0.7
+       net-libs/telepathy-glib
+       >=net-libs/webkit-gtk-2.12.0:4
+       >=x11-libs/gtk+-3.19.12:3
+       x11-libs/pango
+
+       introspection? ( >=dev-libs/gobject-introspection-0.6.2:= )
+       kerberos? (
+               app-crypt/gcr:0=[gtk]
+               app-crypt/mit-krb5 )
+"
+#      telepathy? ( net-libs/telepathy-glib )
+# goa-daemon can launch gnome-control-center
+PDEPEND="gnome? ( >=gnome-base/gnome-control-center-3.2[gnome-online-accounts(+)] )"
+
+DEPEND="${RDEPEND}
+       vala? ( $(vala_depend) )
+       dev-libs/libxslt
+       >=dev-util/gtk-doc-am-1.3
+       >=dev-util/gdbus-codegen-2.30.0
+       >=sys-devel/gettext-0.19.8
+       virtual/pkgconfig
+
+       dev-libs/gobject-introspection-common
+       gnome-base/gnome-common
+"
+
+# Due to sub-configure
+QA_CONFIGURE_OPTIONS=".*"
+
+PATCHES=(
+       "${FILESDIR}"/3.28.0-glib-2.58-compat.patch
+       "${FILESDIR}"/glib-2.58-compat2.patch
+)
+
+src_prepare() {
+       use vala && vala_src_prepare
+       gnome2_src_prepare
+}
+
+src_configure() {
+       # TODO: Give users a way to set the G/FB/Windows Live secrets
+       # telepathy optional support is really a badly one, bug #494456 - now default disabled upstream - revisit soon
+       gnome2_src_configure \
+               --disable-static \
+               --enable-backend \
+               --enable-documentation \
+               --enable-exchange \
+               --enable-facebook \
+               --enable-flickr \
+               --enable-foursquare \
+               --enable-imap-smtp \
+               --enable-lastfm \
+               --enable-media-server \
+               --enable-owncloud \
+               --enable-pocket \
+               --enable-telepathy \
+               --enable-todoist \
+               --enable-windows-live \
+               $(usex debug --enable-debug=yes ' ') \
+               $(use_enable kerberos) \
+               $(use_enable introspection) \
+               $(use_enable vala)
+               #$(use_enable telepathy)
+       # gudev & cheese from sub-configure is overriden
+       # by top level configure, and disabled so leave it like that
+}