gnome-extra/gnome-packagekit: 3.24.0 → 3.30.0

Switched to meson build system. Just translation updates since 3.24.

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Gilles Dartiguelongue <eva@gentoo.org>

diff --git a/gnome-extra/gnome-packagekit/Manifest b/gnome-extra/gnome-packagekit/Manifest
index a30bd9732062f1bd5eacbdd6c7c8cf1d1e413216..0c0d13166ad1d785c1c5b0171f71479876bd29b4 100644 (file)
--- a/gnome-extra/gnome-packagekit/Manifest
+++ b/gnome-extra/gnome-packagekit/Manifest
@@ -1 +1,2 @@
 DIST gnome-packagekit-3.24.0.tar.xz 2174372 BLAKE2B fd6b94c1e2bd9e29c73754e3c1625d6acd4e1931a80c61c572d6f1a90a3c1814cafea1358e64f8cb1be0308d00146716a3a5058a732702b14c3d6a9a0cc98d4a SHA512 af3291b11ad279d050fcd970e1c98257b65da5f36146d8e5f1f255ef1b17e6f2caf8073ce16623da130edaf452860788aa20dd2de6a4bbf639aaf9d3bbd7c095
+DIST gnome-packagekit-3.30.0.tar.xz 1744188 BLAKE2B e346d76a835a84a0b8be46da7af1dba63ef96826e978d06e38490aa44485a010f76b2ed44cde310b8128150f5cf7461cde8007ee5ef7603221f9b947c0e48185 SHA512 69416ccb61effca112ef62ee7a7ba29c262ce768ee41a8bd24a064b66a7106f5e968dc01c6cc3d30d270bd9ebf8cf353044531ad3a19d63b174f097c67edfe9f

diff --git a/gnome-extra/gnome-packagekit/gnome-packagekit-3.30.0.ebuild b/gnome-extra/gnome-packagekit/gnome-packagekit-3.30.0.ebuild
new file mode 100644 (file)
index 0000000..078f468
--- /dev/null
+++ b/gnome-extra/gnome-packagekit/gnome-packagekit-3.30.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome.org gnome2-utils meson virtualx xdg
+
+DESCRIPTION="PackageKit client for the GNOME desktop"
+HOMEPAGE="https://www.freedesktop.org/software/PackageKit/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="systemd test"
+
+RDEPEND="
+       >=dev-libs/glib-2.32:2
+       >=x11-libs/gtk+-3.15.3:3
+       >=app-admin/packagekit-base-0.9.1
+       systemd? (
+               sys-auth/polkit
+               >=sys-apps/systemd-42 )
+"
+DEPEND="${RDEPEND}
+       app-text/docbook-sgml-utils
+       app-text/docbook-sgml-dtd:4.1
+       dev-libs/appstream-glib
+       >=sys-devel/gettext-0.19.7
+       virtual/pkgconfig
+"
+
+# NOTES:
+# app-text/docbook-sgml-utils and dtd required for man pages
+
+# UPSTREAM:
+# see if tests can forget about display (use eclass for that ?)
+
+src_configure() {
+       local emesonargs=(
+               $(meson_use test tests)
+               $(meson_use systemd)
+       )
+       meson_src_configure
+}
+
+src_test() {
+       "${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die
+       GSETTINGS_SCHEMA_DIR="${S}/data" virtx meson_src_test
+}
+
+pkg_postinst() {
+       xdg_pkg_postinst
+       gnome2_schemas_update
+       gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+       xdg_pkg_postrm
+       gnome2_schemas_update
+       gnome2_icon_cache_update
+}