media-libs/libprojectm: Don't install libtool archive files (*.la)

Thanks Polynomial-C

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Craig Andrews <candrews@gentoo.org>

diff --git a/media-libs/libprojectm/libprojectm-3.1.1_rc8-r1.ebuild b/media-libs/libprojectm/libprojectm-3.1.1_rc8-r1.ebuild
new file mode 100644 (file)
index 0000000..ec8f42e
--- /dev/null
+++ b/media-libs/libprojectm/libprojectm-3.1.1_rc8-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="A graphical music visualization plugin similar to milkdrop"
+HOMEPAGE="https://github.com/projectM-visualizer/projectm"
+
+if [[ ${PV} == *9999 ]] ; then
+       EGIT_REPO_URI="https://github.com/projectM-visualizer/projectm.git"
+       inherit git-r3
+else
+       MY_PV="${PV/_/-}"
+       SRC_URI="https://github.com/projectM-visualizer/projectm/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+       KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc64 ~sparc ~x86"
+       S=${WORKDIR}/projectm-${MY_PV}/
+fi
+
+LICENSE="LGPL-2"
+SLOT="0/2"
+IUSE="gles2 qt5 sdl"
+
+RDEPEND="gles2? ( media-libs/mesa[gles2] )
+       media-libs/glm
+       media-libs/mesa[X(+)]
+       qt5? (
+               dev-qt/qtcore:5
+               dev-qt/qtgui:5
+               dev-qt/qtwidgets:5
+               dev-qt/qtopengl:5
+               media-sound/pulseaudio
+       )
+       sdl? ( >=media-libs/libsdl2-2.0.5 )
+       sys-libs/zlib"
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+       virtual/pkgconfig
+"
+
+src_prepare() {
+       default
+       eautoreconf
+}
+
+src_configure() {
+       local myeconfargs=(
+               $(use_enable gles2 gles)
+               $(use_enable qt5 qt)
+               $(use_enable sdl)
+               --enable-emscripten=no
+       )
+       econf "${myeconfargs[@]}"
+}
+
+src_install() {
+       default
+       find "${ED}" -name '*.la' -delete || die
+}

diff --git a/media-libs/libprojectm/libprojectm-9999.ebuild b/media-libs/libprojectm/libprojectm-9999.ebuild
index 19885a4052bc9291ad836e6740746d7b525e910b..ec8f42efd4548e73ea5ece3f7c251247b811c5db 100644 (file)
--- a/media-libs/libprojectm/libprojectm-9999.ebuild
+++ b/media-libs/libprojectm/libprojectm-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -54,3 +54,8 @@ src_configure() {
        )
        econf "${myeconfargs[@]}"
 }
+
+src_install() {
+       default
+       find "${ED}" -name '*.la' -delete || die
+}