sys-libs/compiler-rt-sanitizers: Bump to 4.0.0rc1

diff --git a/sys-libs/compiler-rt-sanitizers/compiler-rt-sanitizers-4.0.0_rc1.ebuild b/sys-libs/compiler-rt-sanitizers/compiler-rt-sanitizers-4.0.0_rc1.ebuild
new file mode 100644 (file)
index 0000000..36f9c15
--- /dev/null
+++ b/sys-libs/compiler-rt-sanitizers/compiler-rt-sanitizers-4.0.0_rc1.ebuild
@@ -0,0 +1,122 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+: ${CMAKE_MAKEFILE_GENERATOR:=ninja}
+# (needed due to CMAKE_BUILD_TYPE != Gentoo)
+CMAKE_MIN_VERSION=3.7.0-r1
+PYTHON_COMPAT=( python2_7 )
+
+inherit cmake-utils flag-o-matic git-r3 python-any-r1
+
+DESCRIPTION="Compiler runtime libraries for clang (sanitizers & xray)"
+HOMEPAGE="http://llvm.org/"
+SRC_URI=""
+EGIT_REPO_URI="http://llvm.org/git/compiler-rt.git
+       https://github.com/llvm-mirror/compiler-rt.git"
+EGIT_BRANCH="release_40"
+EGIT_COMMIT="850646edf7e605354c66693c16ab69193e04a078"
+
+LICENSE="|| ( UoI-NCSA MIT )"
+SLOT="0/${PV%.*}"
+KEYWORDS=""
+IUSE="test"
+
+RDEPEND="!<sys-devel/llvm-${PV}"
+# llvm-4 needed for --cmakedir
+DEPEND="${RDEPEND}
+       >=sys-devel/llvm-4
+       test? (
+               app-portage/unsandbox
+               $(python_gen_any_dep "~dev-python/lit-${PV}[\${PYTHON_USEDEP}]")
+               ~sys-devel/clang-${PV}
+               ~sys-libs/compiler-rt-${PV} )
+       ${PYTHON_DEPS}"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# least intrusive of all
+CMAKE_BUILD_TYPE=RelWithDebInfo
+
+src_unpack() {
+       if use test; then
+               # needed for patched gtest
+               git-r3_fetch "http://llvm.org/git/llvm.git
+                       https://github.com/llvm-mirror/llvm.git" \
+                               c329efbc3c94928fb826ed146897aada0459c983
+       fi
+       git-r3_fetch
+
+       if use test; then
+               git-r3_checkout http://llvm.org/git/llvm.git \
+                       "${WORKDIR}"/llvm
+       fi
+       git-r3_checkout
+}
+
+src_configure() {
+       # pre-set since we need to pass it to cmake
+       BUILD_DIR=${WORKDIR}/${P}_build
+
+       local llvm_version=$(llvm-config --version) || die
+       local clang_version=$(get_version_component_range 1-3 "${llvm_version}")
+       local libdir=$(get_libdir)
+       local mycmakeargs=(
+               -DCOMPILER_RT_INSTALL_PATH="${EPREFIX}/usr/lib/clang/${clang_version}"
+               # use a build dir structure consistent with install
+               # this makes it possible to easily deploy test-friendly clang
+               -DCOMPILER_RT_OUTPUT_DIR="${BUILD_DIR}/lib/clang/${clang_version}"
+
+               -DCOMPILER_RT_INCLUDE_TESTS=$(usex test)
+               # built-ins installed by sys-libs/compiler-rt
+               -DCOMPILER_RT_BUILD_BUILTINS=OFF
+               -DCOMPILER_RT_BUILD_SANITIZERS=ON
+               -DCOMPILER_RT_BUILD_XRAY=ON
+       )
+       if use test; then
+               mycmakeargs+=(
+                       -DLLVM_MAIN_SRC_DIR="${WORKDIR}/llvm"
+                       -DLIT_COMMAND="${EPREFIX}/usr/bin/unsandbox;${EPREFIX}/usr/bin/lit"
+
+                       # they are created during src_test()
+                       -DCOMPILER_RT_TEST_COMPILER="${BUILD_DIR}/bin/clang"
+                       -DCOMPILER_RT_TEST_CXX_COMPILER="${BUILD_DIR}/bin/clang++"
+               )
+
+               # same flags are passed for build & tests, so we need to strip
+               # them down to a subset supported by clang
+               filter-flags -msahf -frecord-gcc-switches
+       fi
+
+       cmake-utils_src_configure
+
+       if use test; then
+               local sys_dir=( "${EPREFIX}/usr/lib/clang/${clang_version}/lib"/* )
+               [[ -e ${sys_dir} ]] || die "Unable to find ${sys_dir}"
+               [[ ${#sys_dir[@]} -eq 1 ]] || die "Non-deterministic compiler-rt install: ${sys_dir[@]}"
+
+               # copy clang over since resource_dir is located relatively to binary
+               # therefore, we can put our new libraries in it
+               mkdir -p "${BUILD_DIR}"/{bin,$(get_libdir),lib/clang/"${clang_version}"/include} || die
+               cp "${EPREFIX}/usr/bin/clang" "${EPREFIX}/usr/bin/clang++" \
+                       "${BUILD_DIR}"/bin/ || die
+               cp "${EPREFIX}/usr/lib/clang/${clang_version}/include"/*.h \
+                       "${BUILD_DIR}/lib/clang/${clang_version}/include/" || die
+               cp "${sys_dir}"/*builtins*.a \
+                       "${BUILD_DIR}/lib/clang/${clang_version}/lib/${sys_dir##*/}/" || die
+               # we also need LLVMgold.so for gold-based tests
+               if [[ -f ${EPREFIX}/usr/$(get_libdir)/LLVMgold.so ]]; then
+                       ln -s "${EPREFIX}/usr/$(get_libdir)/LLVMgold.so" \
+                               "${BUILD_DIR}/$(get_libdir)/" || die
+               fi
+       fi
+}
+
+src_test() {
+       # respect TMPDIR!
+       local -x LIT_PRESERVES_TMP=1
+
+       cmake-utils_src_make check-all
+}

diff --git a/sys-libs/compiler-rt-sanitizers/compiler-rt-sanitizers-9999.ebuild b/sys-libs/compiler-rt-sanitizers/compiler-rt-sanitizers-9999.ebuild
index 212aa4b67ee2493ae67c830bc4799f75cf35305e..83addde698481d27e07ab417d7a215d351367aac 100644 (file)
--- a/sys-libs/compiler-rt-sanitizers/compiler-rt-sanitizers-9999.ebuild
+++ b/sys-libs/compiler-rt-sanitizers/compiler-rt-sanitizers-9999.ebuild
@@ -28,7 +28,7 @@ DEPEND="${RDEPEND}
        >=sys-devel/llvm-4
        test? (
                app-portage/unsandbox
-               $(python_gen_any_dep 'dev-python/lit[${PYTHON_USEDEP}]')
+               $(python_gen_any_dep "~dev-python/lit-${PV}[\${PYTHON_USEDEP}]")
                ~sys-devel/clang-${PV}
                ~sys-libs/compiler-rt-${PV} )
        ${PYTHON_DEPS}"