media-libs/portaudio: update to EAPI 6 and add doc USE flag

diff --git a/media-libs/portaudio/portaudio-19.06.00-r1.ebuild b/media-libs/portaudio/portaudio-19.06.00-r1.ebuild
new file mode 100644 (file)
index 0000000..0a9ef40
--- /dev/null
+++ b/media-libs/portaudio/portaudio-19.06.00-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit ltprune multilib-minimal
+
+DESCRIPTION="A free, cross-platform, open-source, audio I/O library"
+HOMEPAGE="http://www.portaudio.com/"
+SRC_URI="http://www.portaudio.com/archives/pa_stable_v190600_20161030.tgz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~x86-linux"
+IUSE="alsa +cxx debug doc jack oss static-libs"
+
+RDEPEND="alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
+       jack? ( virtual/jack[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+       doc? ( app-doc/doxygen )
+       virtual/pkgconfig"
+
+S=${WORKDIR}/${PN}
+
+DOCS=( README.txt )
+
+multilib_src_configure() {
+       local myeconfargs=(
+               $(use_enable debug debug-output)
+               $(use_enable cxx)
+               $(use_enable static-libs static)
+               $(use_with alsa)
+               $(use_with jack)
+               $(use_with oss)
+       )
+
+       ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+       multilib-minimal_src_compile
+
+       if use doc; then
+               doxygen -u Doxyfile || die
+               doxygen Doxyfile || die
+       fi
+}
+
+multilib_src_install_all() {
+       einstalldocs
+       use doc && dodoc -r doc/html
+       prune_libtool_files
+}