dev-ruby/gpgme: bump for ruby targets

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
Package-Manager: Portage-2.3.16, Repoman-2.3.6

diff --git a/dev-ruby/gpgme/gpgme-2.0.12-r1.ebuild b/dev-ruby/gpgme/gpgme-2.0.12-r1.ebuild
new file mode 100644 (file)
index 0000000..4ca047d
--- /dev/null
+++ b/dev-ruby/gpgme/gpgme-2.0.12-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+USE_RUBY="ruby20 ruby21 ruby22 ruby23 ruby24"
+
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+RUBY_FAKEGEM_EXTRADOC="NEWS README.rdoc"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-ng ruby-fakegem flag-o-matic
+
+DESCRIPTION="Ruby language binding for GnuPG Made Easy"
+HOMEPAGE="https://github.com/ueno/ruby-gpgme"
+SRC_URI="https://github.com/ueno/ruby-gpgme/archive/${PV}.tar.gz -> ruby-${P}.tar.gz"
+RUBY_S="ruby-${P}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND+=">=app-crypt/gpgme-1.1.3"
+RDEPEND+=">=app-crypt/gpgme-1.1.3"
+
+ruby_add_bdepend "test? ( dev-ruby/mocha:0.14 )"
+
+all_ruby_prepare() {
+       sed -i -e '/\(coverall\|bundler\|ruby-debug\|byebug\)/I s:^:#:' \
+               -e '3igem "mocha", "~> 0.14"' \
+               test/test_helper.rb || die
+
+       # Remove failing tests for now. This package was added without
+       # running any tests :-(
+       rm -f test/{ctx,crypto}_test.rb || die
+
+       sed -i -e '/portile/d' ${RUBY_FAKEGEM_GEMSPEC} || die
+}
+
+each_ruby_configure() {
+       append-flags -fPIC
+       export RUBY_GPGME_USE_SYSTEM_LIBRARIES=1
+       ${RUBY} -C ext "${S}/ext/gpgme/extconf.rb" || die "extconf.rb failed"
+}
+
+each_ruby_compile() {
+       emake V=1 -C ext archflag="${LDFLAGS}" || die "emake failed"
+       cp -f "${S}/ext/gpgme_n.so" "${S}/lib" || die
+}
+
+each_ruby_test() {
+       ${RUBY} -Ilib:test:. -e 'Dir["test/*_test.rb"].each{|f| require f}' || die
+}